ActionSnippet | paste it

JS Sketch Experiment

By Zevan | October 5, 2009

Actionscript:

[SWF(width=950, height=600)]
with (graphics) beginFill(0xefefef), drawRect(0,0,stage.stageWidth, stage.stageHeight);
var btn:Sprite = Sprite(addChild(new Sprite()));
with (btn.graphics) beginFill(0x666666), drawRect(0,0,100,20);
with(btn)  x=320, y=430, buttonMode = true;
btn.addEventListener(MouseEvent.ROLL_OVER, function():void{
  with(btn.graphics) clear(), beginFill(0x222222), drawRect(0,0,100,20);
});
btn.addEventListener(MouseEvent.ROLL_OUT, function():void{
  with(btn.graphics) clear(), beginFill(0x666666), drawRect(0,0,100,20);
});
btn.addEventListener(MouseEvent.CLICK, function():void{
    var res:*= ExternalInterface.call("function(){ plot=[]; colors=[]; " + txt.text + " return {plot:plot, colors:colors};}");
    render((res == null) ? {plot:[], colors:[]} : res);
});
 
var v:Shape = Shape(addChild(new Shape()));
v.x = 700;
v.y = 220;
function render(obj:Object):void{
    var plot:Array = obj.plot;
    var colors:Array = obj.colors;
    var leng:int = plot.length;
    v.graphics.clear();
    var inc:int = 0;
    v.graphics.moveTo(plot[0], plot[1]);
    for (var i:int = 2; i<leng; i+=2){
        v.graphics.lineStyle(0,colors[inc++]);
        v.graphics.lineTo(plot[i], plot[i + 1]);
    }
}
 
 
var submit:TextField = TextField(btn.addChild(new TextField()));
submit.defaultTextFormat = new TextFormat("_sans", 12);
with(submit) textColor=0xFFFFFF, width=100, autoSize="center";
with(submit) mouseEnabled = false,  text="submit";
 
var txt:TextField = TextField(addChild(new TextField()));
with(txt) x = y = 20, type = "input", multiline=true;
with(txt) width = 400, height = 400, border = true, background = 0xFFFFFF;
txt.defaultTextFormat = new TextFormat("Monaco", 12);
txt.text = "enter text"; 
txt.addEventListener(MouseEvent.MOUSE_DOWN, onDown);
function onDown(evt:MouseEvent):void{
    txt.text = "";
    txt.removeEventListener(MouseEvent.MOUSE_DOWN, onDown);
}

This snippet is a mini code editor that allows the user to write javascript into a textfield - the javascript is then run using external interface. Optionally the javascript code can populate two arrays (plot and colors). If these arrays are populated flash, will render the data in each array using the Graphics class.

Have a look at the demo:

If you do something nice with this... post your javascript snippet as a comment and I'll add it to the JS Sketch page...

Posted in Graphics, Math, dynamic, external data, functions | Tagged actionscript, as3, flash, javascript | Leave a comment

ActionScript Eval (well, not really)

By Zevan | October 3, 2009

CLICK HERE TO COPY

Actionscript:

var txt:TextField = TextField(addChild(new TextField()));
txt.autoSize = TextFieldAutoSize.LEFT;
 
var myVar:Number = 100;
// works as an expression parser
txt.text = js("return (" + myVar + " * 2 + 10) / 2");
txt.appendText("\n\n");
 
// parses javascript
txt.appendText(js("var a = []; for (var i = 0; i<10; i++){ a.push(i) } return a;"));
 
function js( data:String ):*{
   var res:*= ExternalInterface.call("function(){" + data + "}");
   return (res == null) ? "null" : res;
}

This one made my day - CAN'T believe I never thought of it before... haven't done any speed tests yet... but it shows how to use ExternalInterface.call to parse math expressions and javascript code. This will only work when the swf is shown in an html page of course... so if your in flash cmd+f12...

I got the idea from this code snippet... which actually has an error in it... the decode() function should not return void... I found that snippet thanks to this tweet by makc3d.

Posted in Math, external data, functions, misc, string manipulation, strings | Tagged actionscript, flash, javascript | Leave a comment

E8 Inspired Forms

By Zevan | October 2, 2009

This doesn't have much to do with E8.. but it is vaguely inspired by it...

View the demo... (source code is below)

CLICK HERE TO COPY

Actionscript:

var hw:Number = stage.stageWidth / 2;
var hh:Number = stage.stageHeight / 2;
 
var canvas:BitmapData = new BitmapData(stage.stageWidth,stage.stageHeight, false, 0x333333);
addChild(new Bitmap(canvas));
var vector:Shape = Shape(addChild(new Shape()));
 
// contrast
var cm:ColorMatrixFilter = new ColorMatrixFilter([2.6,0,0,0,-101.6,0,2.6,0,0,-101.6,0,0,2.6,0,-101.6,0,0,0,1,0]);
filters = [cm];
 
var over:BitmapData = new BitmapData(stage.stageWidth,stage.stageHeight, false, 0x333333);
var frm:Bitmap = Bitmap(addChild(new Bitmap(over)));
 
frm.blendMode = BlendMode.OVERLAY;
 
var dotNum:int = 250;
var dotConnected:int = 0;
var curr:int = 0;
var prevConnected:int = -1;
var dots:Vector.<Point> = new Vector.<Point>(dotNum, true);
 
// consider altering this value manually
var step:Number =  Math.random()*10
 
var theta:Number = -.5234;
for (var i:int= 0; i <dotNum; i++){
    var r:Number = 280
    theta += step;
    var xp:Number = hw + r  * Math.cos(theta);
    var yp:Number = hh + r * Math.sin(theta);
    dots[i] = new Point(xp, yp);
}
 
var col:uint = 0xFFFFFF;
var a:Point, b:Point;
var connections:int = 0;
 
var txt:TextField = TextField(addChild(new TextField()));
txt.defaultTextFormat = new TextFormat("_sans", 12);
txt.textColor = 0x555555, txt.x = 10, txt.y = 10;
txt.autoSize = "left";
txt.text = step.toString();
 
addEventListener(Event.ENTER_FRAME, onLoop);
function onLoop(evt:Event):void{
     
    over.applyFilter(canvas, over.rect, new Point(0,0), new BlurFilter(10,10, 1));
    
    for (var i:int = 0; i<100; i++){
        if (dotConnected <dotNum - 1){
            if (prevConnected != dotConnected){
                a = dots[dotConnected];
            }
            prevConnected = dotConnected;
            b = dots[curr];
            curr++;
            
            if (a != b){
                connections++;
                vector.graphics.clear();
                vector.graphics.lineStyle(0,col,0.05);
                vector.graphics.moveTo(a.x, a.y);
                vector.graphics.lineTo(b.x, b.y);
                canvas.draw(vector); 
            }
            if (curr> dotNum - 1){
                curr = 0;
                dotConnected++;
                col =[0,0xFFFFFF][int(Math.random()*2)];
            } 
        }else{
            break;
            trace("done");
            removeEventListener(Event.ENTER_FRAME, onLoop);
        }
    }
}

Posted in BitmapData, Math, misc | Tagged actionscript, as3, flash | Leave a comment

QuickBox2D Mini-Machine

By Zevan | October 1, 2009

Since this is a rather large snippet check out this demo first:

View Demo...

and here is the source:

CLICK HERE TO COPY

Actionscript:

import com.actionsnippet.qbox.*
import Box2D.Collision.Shapes.*;
import Box2D.Common.Math.*;
 
[SWF(width = 800, height = 600, backgroundColor = 0x000000, frameRate = 60)]
 
var sim:QuickBox2D = new QuickBox2D(this, {debug:true});
 
var sw:Number = stage.stageWidth / 30;
var sh:Number = stage.stageHeight / 30;
            
sim.addBox({x:sw / 2, y:sh, width:sw - 3, height:1,  density:.0})
sim.addBox({x:sw / 2, y:0, width:sw - 3, height:1,  density:.0 })
sim.addBox({x:0, y:sh / 2, width:1, height:sh ,  density:.0})  
sim.addBox({x:sw, y:sh / 2, width:1, height:sh,  density:.0})  
 
var slider:QuickObject = sim.addBox({x:3, y:6, width:6, height:0.25, density:0, angle:0.05});
var pusher:QuickObject = sim.addBox({x:15, y:18, width:4, height:4, density:0});
 
sim.setDefault({collideConnected:false, frequencyHz:10});
var anchor:QuickObject = sim.addCircle({x:3, y:2, radius:0.2, density:0});
 
var m0:QuickObject = sim.addBox({x:3, y:5, width:1, height:0.25, fixedRotation:true});
 
var j0:QuickObject = sim.addJoint({type:"distance", a:anchor.body, b:m0.body});
 
var m1:QuickObject = sim.addBox({x:2.5, y:9.5, width:0.25, height:6, fixedRotation:true});
var m2:QuickObject = sim.addBox({x:3.5, y:9.5, width:0.25, height:6, fixedRotation:true});
 
var j1:QuickObject = sim.addJoint({type:"distance", a:m0.body, b:m1.body});
var j2:QuickObject = sim.addJoint({type:"distance", a:m0.body, b:m2.body});
var j3:QuickObject = sim.addJoint({type:"distance", a:m2.body, b:m1.body});
 
var boxes:Array = [];
var boxNum:int = 21;
var index:int = boxNum;
var filter:b2FilterData;
var lookupQuickObject:Dictionary = new Dictionary();
for (var i:int = 0; i<boxNum; i++){
    boxes[i] = sim.addBox({x:3, y:6.3 + i * 0.3, width:0.6, height:0.3,  friction:0.0, allowSleep:false});
    lookupQuickObject[boxes[i].shape] = boxes[i];
}
 
var m3:QuickObject = sim.addBox({x:3, y:12.25 , width:1, height:0.25, allowSleep:false,fixedRotation:true, groupIndex:-1});
 
var j4:QuickObject = sim.addJoint({type:"revolute", a:m1.body, b:m3.body});
var j5:QuickObject = sim.addJoint({type:"revolute", a:m2.body, b:m3.body});
 
var t:Number = Math.PI;
var dropBox:int = 0;
var prevBox:QuickObject;
var resetVec:b2Vec2 = new b2Vec2(0,0);
 
function setGroupIndex(b:QuickObject, index:int):void{
    filter = b.shape.GetFilterData();
    filter.groupIndex = index;
    b.shape.SetFilterData(filter);
}
 
sim.start();
sim.addEventListener(QuickBox2D.STEP, onStep);
function onStep(evt:Event):void{
    dropBox++;
    
    if (dropBox % 80 == 0){
        index--;
        if (index> -1){
            if (prevBox){
                setGroupIndex(prevBox, 1);
            }
            prevBox = boxes[index]
            setGroupIndex(boxes[index], -1);
            m3.y += 0.05;
        }
    }
    
    if (index <0){
        if (pusher.x> 3.5){
            pusher.x -= 0.05;
        }
    }
    for (var i:int = 0; i<boxNum; i++){
        if (boxes[i].y> 22){
            boxes[i].angle = 0;
            boxes[i].y = -2;
            boxes[i].x = 1;
            boxes[i].body.SetLinearVelocity(resetVec);
        }
    }
    
    if (index> 0){
      anchor.x = 6 + 3 * Math.cos(t);
      t += 0.01;
    }
}

Posted in Box2D, QuickBox2D | Tagged actionscript, as3, Box2D, flash, QuickBox2D | 9 Comments

paste it

JS Sketch Experiment

ActionScript Eval (well, not really)

E8 Inspired Forms

QuickBox2D Mini-Machine

Search

Pages

Recent Posts

Categories

Archives

RSS Feeds