Browse the notebook

Tag: bezier

JavaScript Smooth Quadratic Bezier

By Zevan

Being able to draw smooth lines that connect arbitrary points is something that I find myself needing very frequently. This is a port of an old snippet that does just that. By averaging control points of a quadratic bezier curve we ensure that our resulting Bezier curves are always smooth.

The key can be seen here with the `bezierSkin` function. It draws either a closed or open curve.

// array of xy coords, closed boolean
function bezierSkin(bez, closed = true) {
  var avg = calcAvgs(bez), 
      leng = bez.length,
      i, n;

  if (closed) {
    c.moveTo(avg[0], avg[1]);
    for (i = 2; i < leng; i += 2) {
      n = i + 1;
      c.quadraticCurveTo(bez[i], bez[n], avg[i], avg[n]);
    }
    c.quadraticCurveTo(bez[0], bez[1], avg[0], avg[1]);
  } else {
    c.moveTo(bez[0], bez[1]);
    c.lineTo(avg[0], avg[1]);
    for (i = 2; i < leng - 2; i += 2) {
      n = i + 1;
      c.quadraticCurveTo(bez[i], bez[n], avg[i], avg[n]);
    }
    c.lineTo(bez[leng - 2], bez[leng - 1]);
  }
}


// create anchor points by averaging the control points
function calcAvgs(p) {
  var avg = [],
      leng = p.length, prev;
  for (var i = 2; i < leng; i++) {
    prev = i - 2;
    avg.push((p[prev] + p[i]) / 2);
  }
  // close
  avg.push((p[0] + p[leng - 2]) / 2);
  avg.push((p[1] + p[leng - 1]) / 2);
  return avg;
}

The control points are then averaged to ensure that the curve contains no sharp angles.

Read snippet: JavaScript Smooth Quadratic Bezier

Bezier Skin (smooth curveTo())

By Zevan
// graphics, vector of xy coords, closed boolean
function bezierSkin(g:Graphics, bez:Vector.<Number>, closed:Boolean = true):void {
	var avg:Vector.<Number> = calcAvgs(bez);
	var i:int, n:int;
	var leng:int = bez.length;

	if (closed){
		g.moveTo(avg[0], avg[1]);
		for (i = 2; i < leng; i+=2) {
			n=i+1;
			g.curveTo(bez[i], bez[n], avg[i], avg[n]);
		}
		g.curveTo(bez[0], bez[1], avg[0], avg[1]);
	}else{
		g.moveTo(bez[0], bez[1]);
	    g.lineTo(avg[0], avg[1]);
		for (i = 2; i < leng-2; i+=2) {
			n=i+1;
			g.curveTo(bez[i], bez[n], avg[i], avg[n]);
		}
		g.lineTo(bez[ leng - 2], bez[ leng - 1]);
	}
}

// create anchor points by averaging the control points
function calcAvgs(v:Vector.<Number>):Vector.<Number> {
	var avg:Vector.<Number> = new Vector.<Number>();
	var leng:int=v.length;
	for (var i:int = 2; i<leng; i+=1) {
		var prev:Number=i-2;
		avg.push( (v[prev] + v[i]) / 2 );
	}
	// close
	avg.push( (v[0] + v[ leng - 2]) / 2 );
	avg.push( (v[1] + v[ leng - 1]) / 2 );
	return avg;
}

// test out the functions:

graphics.lineStyle(0,0x000000);

// draw a very rounded rect
bezierSkin(graphics, Vector.<Number>([100,100,200,100,200,200,100,200]) );

// draw a random curve with 10 xy coords
var rnd:Vector.<Number> = new Vector.<Number>();
for (var i:int = 0; i<20; i++) rnd.push(Math.random()*100);
bezierSkin(graphics, rnd);
						
// erase everything and allow the used to draw a smooth curve with the mouse
stage.addEventListener(MouseEvent.MOUSE_DOWN, onLoop);
var index:int = 0;
var pnts:Vector.<Number> = new Vector.<Number>();

function onLoop(evt:MouseEvent):void {
	 pnts.push(mouseX);
	 pnts.push(mouseY);
	
     graphics.clear();
	 graphics.lineStyle(0,0x000000);
	 
	  // draw a smooth curved line
	 bezierSkin(graphics,pnts,false);
}

The above code uses averaging to generate anchor points for curveTo() calls. This is an easy way to always draw smooth curves.

This is an old one that I’ve seen floating around since the drawing api first came out… but I it’s an important snippet, so I figured I’d post it.

Read snippet: Bezier Skin (smooth curveTo())

Quadratic Bezier

By Zevan
var canvas:BitmapData=new BitmapData(280,280,false,0x000000);
addChild(new Bitmap(canvas, PixelSnapping.AUTO, true));
var color:uint;
// anchor x1, anchor y1,
// control-handle x2, control-handle y2,
// anchor x3, anchor y3, [resolution incremental value between 0-1]
function quadBezier(x1:Number, y1:Number, x2:Number, y2:Number, x3:Number, y3:Number, resolution:Number=.03):void {
	var b:Number,pre1:Number,pre2:Number,pre3:Number,pre4:Number;
	for (var a:Number = 0; a <1;a+=resolution) {
	
		b=1-a;
		pre1=(a*a);
		pre2=2*a*b;
		pre3=(b*b);
		
		canvas.setPixel(pre1*x1 + pre2*x2  + pre3*x3 ,
						             pre1*y1 + pre2*y2 + pre3*y3, color);
	}
}

// draw a few
color = 0xFFFFFF;

for (var i:int = 0; i<20; i++){
quadBezier(40,100, 150 , 20 + i * 10 , 200, 100,.01);
}

color = 0xFF0000;

for (i= 0; i<20; i++){
quadBezier(150,200, 100 + i * 10, 100  , 120, 30,.01);
}

The above demos a function that draws quadratic bezier curves using setPixel().

One of the first posts on this site was a snippet that used setPixel() to draw a cubic bezier curve. I recently needed to do the exact same thing but I wanted to use a quadratic bezier… I knew I had the code laying around somewhere, but I couldn’t seem to find it so I just looked on wikipedia and changed the previous cubicBezier() function accordingly.

Read snippet: Quadratic Bezier