By Zevan | February 10, 2009
Actionscript:
-
function nest(top:DisplayObjectContainer, structure:Array):void{
-
var p:DisplayObjectContainer;
-
var key:String;
-
for (var i:int = 0; i<structure.length; i++){
-
if (structure[i] is DisplayObjectContainer){
-
p = structure[i];
-
if (!p.parent){
-
top.addChild(p);
-
}
-
i++;
-
if (structure[i] is Array){
-
var child:DisplayObject;
-
for (var j:int= 0; j<structure[i].length; j++){
-
var val:* = structure[i][j];
-
if (val is DisplayObject){
-
child = val;
-
p.addChild(child);
-
}else{
-
for (key in val){
-
child[key] = val[key];
-
}
-
}
-
}
-
}else{
-
trace("error, expecting Array");
-
break;
-
}
-
}else{
-
trace("error, expecting DisplayObjectContainer (Sprite or MovieClip)");
-
break;
-
}
-
}
-
}
-
-
// create some filler graphics
-
var window:Sprite = createWindow();
-
window.x = 10;
-
window.y = 10;
-
-
var c0:Sprite = createCircle();
-
var c1:Sprite = createCircle();
-
var c2:Sprite = createCircle();
-
var c3:Sprite = createCircle();
-
var c4:Sprite = createCircle(0xEFEFEF);
-
-
var box:Sprite = createBox(60, 50);
-
-
-
var txt:TextField = new TextField();
-
txt.text = "HI THERE";
-
-
// test out the function....
-
nest(this, [window, [ c0, {x:100, y:100, scaleX:.5, scaleY:.5},
-
c1, {x:120, y:100, scaleX:.6, scaleY:.6},
-
c2, {x:140, y:100, scaleX:.7, scaleY:.7},
-
c3, {x:160, y:100, scaleX:.8, scaleY:.8},
-
box, {x:10, y:10} ],
-
box, [ txt, c4,{x :30, y:30} ] ]);
-
-
-
// just some quick functions to create filler graphics
-
-
function createBox(w:Number, h:Number):Sprite{
-
var s:Sprite = new Sprite();
-
with(s.graphics) beginFill(0x666666), drawRect(0,0, w, h);
-
return s;
-
}
-
function createWindow():Sprite{
-
var s:Sprite = new Sprite();
-
with(s.graphics) beginFill(0xCCCCCC), drawRect(0,0,300,300);
-
return s;
-
}
-
function createCircle(col:uint = 0xFF0000):Sprite{
-
var s:Sprite = new Sprite();
-
with(s.graphics) beginFill(col), drawCircle(0,0,10);
-
return s;
-
}
The above uses a function called nest(). nest() is sort of like a superAddChild() function... it is meant to do the same thing as addChild, but with any number of parents and children.
I'm actually not very happy with this function, it was fun to write... but the 2D-Array/Object format is kind of odd looking (see line 53). So for at least the next day or two I'm going to try and think of the best format for a function that could do any number of addChild() calls with any number of children or parents. I realized that I also want to be able to set the properties of any of the children... so one solution might be an xml argument... something like:
Actionscript:
-
<window>
-
<c0 x="100" y="100" />
-
<c1 x="200" y="100" />
-
<c2 x="300" y="100" />
-
<box x="400" y="100" alpha=".5">
-
<c3 x="10" y="10" />
-
</box>
-
</window>
That's easy enough to do... it would be nice to think of something more minimalistic, but I think XML is much easier to read than JSON style Object syntax...
It's actually interesting to try and think of minimalistic ways to represent tree structures... check out this failed attempt:
Actionscript:
-
p(window);
-
__(c0, {x:100, y:100});
-
__(c1, {x:100, y:100});
-
__(c2, {x:100, y:100});
-
-
p(__(box, {x:100, y:100}));
-
__(txt, c4, {x:30, y:30});
After writing the above... a few hours later I thought of this:
Actionscript:
-
propOrder("x", "y", "scaleX", "scaleY", "alpha");
-
-
bigInit(this, [window, [info, 10, 10,
-
about, 20, 10,
-
contact, 30, 10,
-
box, 40, 10, 2, 2, .5],
-
box, [txt0, 10, 10 * off(),
-
txt1, 10, 10 * off(),
-
txt2, 10, 10 * off(),
-
txt3, 10, 10 * off()],
-
border]);
I think that's pretty close to what I was imagining in terms of simplicity.. the off() function would return an incremental offset... so call it once and it's 0, call it again and it's 1 etc... still not completely happy with this, but it's getting there...
Any additional thoughts on this topic will be in tomorrows post I think.
Posted in misc | Tagged actionscript, flash |
By Zevan | February 9, 2009
Actionscript:
-
var obj:Object = {name: "Joe", hobby: "Guitar", age:"80"};
-
-
if ("name" in obj){
-
trace(obj, " has a name property");
-
}
-
-
if ("x" in obj == false){
-
trace(obj, " doesn't have an x property");
-
}
-
-
-
var mySprite:Sprite = new Sprite();
-
-
if ("currentFrame" in mySprite == false){
-
trace(mySprite, "does not have a currentFrame property");
-
}
The "in" operator can be used to check if an object has a specific property. In the above example I test a standard Object instance and a Sprite instance for a few different properties.
I could see this operator being used when dealing with * (wildcard) datatypes and dynamic style code....
By Zevan | February 8, 2009
Actionscript:
-
var encode:Object = new Object();
-
var decode:Object = new Object();
-
var a:Array = " abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890".split("");
-
-
// change this for different encoded results
-
var offset:int = 10;
-
-
for (var i:int = 0; i<a.length; i++){
-
var index:int = (a.length - i - offset) % a.length;
-
encode[a[i]] = a[index];
-
decode[a[index]] = a[i];
-
}
-
-
function encodeString(str:String):String{
-
return map(str, encode);
-
}
-
-
function decodeString(str:String):String{
-
return map(str, decode);
-
}
-
-
function map(str:String, smode:Object):String{
-
var n:String = "";
-
for (var i:int = 0; i<str.length; i++){
-
var char:String = str.charAt(i);
-
var en:String = smode[char];
-
if (en){
-
n += en;
-
}else{
-
n += char;
-
}
-
}
-
return n;
-
}
-
-
// test out the functions
-
-
var input:String = "This is a regular string";
-
-
trace(input);
-
-
var encoded:String = encodeString(input);
-
-
trace("encoded: ", encoded);
-
-
trace("decoded: ",decodeString(encoded));
-
-
/*
-
outputs:
-
-
This is a regular string
-
encoded: gSRH1RH1Z1IVTFOZI1HGIRMT
-
decoded: This is a regular string
-
-
*/
The above demos an intentionally simple string encoding technique.
This is a technique I use if I need to encode strings but don't care if someone figures out what the string value actually is. For me, this is more common than needing hard/impossible to crack string encoding algorithms. A good example is an e-card... a url for an ecard could look like this:
www.birthdaycardthing.com/?name=joe&age=32
or it could look like this:
www.birthdaycardthing.com/?i=brx&x=5p
I wrapped this snippet up into a class and made a few minor tweaks. The class is called SimpleCipher it has two static methods and one static property...
Actionscript:
-
import com.actionsnippet.utils.SimpleCipher;
-
// same as offset above, but can be set at any time
-
// new encode and decode Objects will be calculated
-
SimpleCipher.offset = 1;
-
var input:String = "SimpleCipher encoding and decoding";
-
-
trace("input: ", input);
-
-
var encoded:String = SimpleCipher.encode(input);
-
-
trace("encoded: ", encoded);
-
trace("decoded: ", SimpleCipher.decode(encoded));
-
/*
-
outputs:
-
input: SimpleCipher encoding and decoding
-
encoded: RhlokdBhogdq0dmbnchmf0 mc0cdbnchmf
-
decoded: SimpleCipher encoding and decoding
-
*/
Download SimpleCipher Class
(this class uses a static initializer... see yesterdays post)
By Zevan | February 7, 2009
Actionscript:
-
package{
-
-
public class Lookup{
-
-
private static var _random:Array;
-
// static initializer
-
{
-
trace("I am a static initializer for " + Lookup);
-
init();
-
}
-
-
private static function init():void{
-
_random = new Array();
-
// generate some filler values
-
for (var i:int = 0; i<100; i++){
-
_random.push(Math.random() * i);
-
}
-
}
-
-
public static function get random():Array{
-
return _random.concat();
-
}
-
}
-
}
...and to test out the above class:
Actionscript:
-
package {
-
import flash.display.Sprite;
-
-
public class Main extends Sprite{
-
public function Main(){
-
trace(Lookup.random[50]);
-
}
-
}
-
}
-
/*
-
outputs:
-
I am a static initializer for [class Lookup]
-
5.4258062043227255
-
*/
The above shows how to use static initializers. I've found this to be very handy... in this case we create an array of random values....
Tomorrow I'll actually post a real class where I make use of this... the Lookup class in this case is really just filler code....
Posted in OOP | Tagged actionscript, flash |