Tag Archives: as3

I want Twitter

By Zevan | August 3, 2009

Actionscript:

[SWF(width = 800, height=600, frameRate=15)]
 
var littleTxt:TextField = TextField(addChild(new TextField()));
with (littleTxt){
    defaultTextFormat = new TextFormat("_sans", 10);
    width = stage.stageWidth-20;
    height = stage.stageHeight-20;
    multiline = true;
    wordWrap = true;
    text ="";
    textColor = 0x444444;
    selectable = false;
    x = y = 10;
}
 
var txt:TextField = TextField(addChild(new TextField()));
with (txt){
    defaultTextFormat = new TextFormat("_sans", 90);
    autoSize = "center";
    x = 0
    y = stage.stageHeight / 2 - 61
    width = stage.stageWidth;
    selectable = false;
    text = "loading";
}
 
var selectWords:Array = [];
addEventListener(Event.ENTER_FRAME, onLoop);
function onLoop(evt:Event):void {
     if (selectWords.length> 0){
        var word:String = selectWords[int(Math.random() * selectWords.length)];
        txt.text = word;
        littleTxt.appendText(word+" ");
     }
}
 
var loader:URLLoader = new URLLoader();
var req:URLRequest = new URLRequest("http://search.twitter.com/search.atom");
var vars:URLVariables = new URLVariables();
vars.q = "i want";
// results per page
vars.rpp = "50";
vars.page = 1;
vars.lang = "en";
 
req.data = vars;
req.method = URLRequestMethod.POST;
loader.load(req);
loader.addEventListener(Event.COMPLETE, onLoaded);                                  
function onLoaded(evt:Event):void{
    var searchData:XML = new XML(loader.data);
    var atom:Namespace = searchData.namespace("");
    default xml namespace = atom;
    var titles:String = "";
    for each(var entry:XML in searchData.entry){
        titles += entry.title.toString();
    }
    var index:int = 0;
    var words:Array = titles.split(" ");
    for (var i:int = 0; i<words.length; i++){
        // exclude a few things
        if (words[i].match(/RT|\@|\#|http/g).length == 0){
            selectWords[index++] = words[i];
        }
    }
}

This snippet searches twitter for the phrase "I want" and then displays the results randomly word by word in a somewhat hypnotic way.

Have a look at the swf...

Posted in external data, string manipulation, strings | Also tagged actionscript, flash, twitter | 5 Comments

I’m Twitter Search

By Zevan | August 1, 2009

CLICK HERE TO COPY

Actionscript:

[SWF(width = 400, height=600, frameRate=12)]
var loader:URLLoader = new URLLoader();
var req:URLRequest = new URLRequest("http://search.twitter.com/search.atom");
var vars:URLVariables = new URLVariables();
vars.q = "I'm";
// results per page
vars.rpp = "7";
vars.page = 1;
 
req.data = vars;
req.method = URLRequestMethod.GET;
 
loader.addEventListener(Event.COMPLETE, onLoaded);
loader.load(req);
 
// check for updates every 30 seconds - 
var timer:Timer = new Timer(30000);
timer.addEventListener(TimerEvent.TIMER, onTick);
timer.start();
function onTick(evt:TimerEvent):void{
    txt.htmlText = "loading...";
    loader.load(req);
}
 
var txt:TextField = TextField(addChild(new TextField()));
txt.defaultTextFormat = new TextFormat("_sans", 12);
with (txt){ x=10, y=10, width=stage.stageWidth-10;
height=stage.stageHeight, multiline = true, wordWrap = true; }
txt.htmlText = "loading...";
                                                    
function onLoaded(evt:Event):void{
    var searchData:XML = new XML(loader.data);
    var atom:Namespace = searchData.namespace("");
    default xml namespace = atom;
    var htmlText:String = "<b>Last " + vars.rpp + " '" + vars.q + "' tweets:</b><br><br>";
    for each(var entry:XML in searchData.entry){
        htmlText += entry.author.name.toString() + ": <br>";
        htmlText += entry.title.toString() + "<br><br>";
    }
    txt.htmlText = htmlText; 
}

Was curious about the twitter search api so spent a few minutes and whipped up a quick demo - the api is simple and easy to understand...

As a test I created something that shows the last 7 tweets including the phrase I'm. A new search is done every 30 seconds... I chose the phrase I'm so that there will be different results every time a new search is done...

Posted in XML, external data | Also tagged actionscript, flash, twitter | 1 Comment

Perlin Outlines

By Zevan | July 31, 2009

CLICK HERE TO COPY

Actionscript:

[SWF(width = 600, height=600, backgroundColor=0xCCCCCC, frameRate=24)]
var canvas:BitmapData = new BitmapData(stage.stageWidth,stage.stageHeight, false, 0x000000);
var blur:BitmapData = new BitmapData(stage.stageWidth,stage.stageHeight, false, 0x000000);
addChild(new Bitmap(canvas, "auto", true));
 
var w:int = canvas.width 
var hw:int = w / 2;
var size:int = w * w;
var seed:Number = Math.random()*100;
var pnt:Point = new Point();
var dy:Number = 0, dx:Number = 0;
var blr:BlurFilter = new BlurFilter(10,10,1);
addEventListener(Event.ENTER_FRAME, onLoop);
function onLoop(evt:Event):void {
    
    dx += (mouseX - dx) / 4;
    dy += (mouseY - dy) / 4;
    canvas.lock();
    canvas.perlinNoise(hw,hw,2,seed,false, false, 1, true, [new Point(dx, dy), new Point(-dx, -dy)]);
    var pix:Vector.<uint> = canvas.getVector(canvas.rect);
    for (var i:int = 0; i<size; i++){
        var col:uint = 255 - pix[i] <<4 & 0x00FF00;
        pix[i] = col <<8 | col | col>> 8;
    }
    canvas.setVector(canvas.rect, pix);
    blur.copyPixels(canvas, canvas.rect, pnt);
    blur.applyFilter(blur, blur.rect, pnt, blr);
    canvas.draw(blur, null, null, BlendMode.DIFFERENCE);
    canvas.draw(canvas, null, null, BlendMode.INVERT);
    canvas.unlock();
}

This is actually an optimized variation on some recent posts that made use of perlin noise. You can get a wide range of effects by changing just the BlendMode values alone.... I particularly like this combination of BlendModes because it reminds me a bit of a terrain map...

Have a look at the swf...

Posted in BitmapData, Vector, pixel manipulation | Also tagged actionscript, flash | Leave a comment

Parallax fp10

By Zevan | July 30, 2009

CLICK HERE TO COPY

Actionscript:

[SWF(backgroundColor=0x000000, width = 800, height = 600)]
 
// this is a trick to keep the 3D texture quality up... 
// try setting it right off the bat and you'll notice that the
// Shapes look pixilated
setTimeout(function():void{ stage.quality="low"}, 500);
 
var matrix:Matrix = new Matrix();
matrix.createGradientBox(600, 600, 0, -450, -450);
 
var boxNum:int = 30;
var boxes:Array = [];
for (var i:int = 0; i<boxNum; i++) boxes[i] = makeBox();
 
var dx:Number = 0, dy:Number = 0;
onLoop();
addEventListener(Event.ENTER_FRAME, onLoop);
 
function onLoop(evt:Event=null):void {
    dx += (mouseX - dx) / 4;
    dy += (mouseY - dy) / 4;
    for (var i:int = 0; i<boxNum; i++){
        var box:Shape = boxes[i];
        box.z = 400 - i * 20;
        box.x = dx;
        box.y = dy;
        box.rotation = i + getTimer() / 10;
    }
}
 
function makeBox():Shape{
    var box:Shape = Shape(addChild(new Shape()));
    box.x = stage.stageWidth/2;
    box.y = stage.stageHeight/2;
    box.z = 1;
    with (box.graphics){
         beginGradientFill(GradientType.RADIAL, [0xFFFFFF, 0x333333], [1,1], [0, 255], matrix, SpreadMethod.PAD);
        drawRect(-100, -100, 200, 200);
        drawRect(-70, -70, 140, 140);
    }
    return box;
}

This snippet draws 30 gradient box shapes, gives them different z values and then moves them based on the mouse. This technique is good if you just want a few layers of parallax motion - I got carried away and you'll notice that if you add more boxes it begins to slow down pretty quick.

Have a look at the swf....

I first used this technique for this small interactive drawing...

Something interesting I noticed about fp10 3D DisplayObjects is that if you set the stage.quality to low right off the bat, the display objects look pixelated... but if you wait a few milliseconds, you end up with less pixelation and you still get a speed boost from the low quality - I think it must have something to do with the way the 3D textures are handled by the player...

Tomorrow I think I'll post a version of this that uses IGraphicsData and Utils.projectVectors()... should be a huge speed boost...

Posted in 3D, motion | Also tagged actionscript, flash | 1 Comment

Tag Archives: as3

I want Twitter

I’m Twitter Search

Perlin Outlines

Parallax fp10

Search

Pages

Recent Posts

Categories

Archives

RSS Feeds