Category Archives: external data

JS Sketch Experiment

By Zevan | October 5, 2009

Actionscript:

[SWF(width=950, height=600)]
with (graphics) beginFill(0xefefef), drawRect(0,0,stage.stageWidth, stage.stageHeight);
var btn:Sprite = Sprite(addChild(new Sprite()));
with (btn.graphics) beginFill(0x666666), drawRect(0,0,100,20);
with(btn)  x=320, y=430, buttonMode = true;
btn.addEventListener(MouseEvent.ROLL_OVER, function():void{
  with(btn.graphics) clear(), beginFill(0x222222), drawRect(0,0,100,20);
});
btn.addEventListener(MouseEvent.ROLL_OUT, function():void{
  with(btn.graphics) clear(), beginFill(0x666666), drawRect(0,0,100,20);
});
btn.addEventListener(MouseEvent.CLICK, function():void{
    var res:*= ExternalInterface.call("function(){ plot=[]; colors=[]; " + txt.text + " return {plot:plot, colors:colors};}");
    render((res == null) ? {plot:[], colors:[]} : res);
});
 
var v:Shape = Shape(addChild(new Shape()));
v.x = 700;
v.y = 220;
function render(obj:Object):void{
    var plot:Array = obj.plot;
    var colors:Array = obj.colors;
    var leng:int = plot.length;
    v.graphics.clear();
    var inc:int = 0;
    v.graphics.moveTo(plot[0], plot[1]);
    for (var i:int = 2; i<leng; i+=2){
        v.graphics.lineStyle(0,colors[inc++]);
        v.graphics.lineTo(plot[i], plot[i + 1]);
    }
}
 
 
var submit:TextField = TextField(btn.addChild(new TextField()));
submit.defaultTextFormat = new TextFormat("_sans", 12);
with(submit) textColor=0xFFFFFF, width=100, autoSize="center";
with(submit) mouseEnabled = false,  text="submit";
 
var txt:TextField = TextField(addChild(new TextField()));
with(txt) x = y = 20, type = "input", multiline=true;
with(txt) width = 400, height = 400, border = true, background = 0xFFFFFF;
txt.defaultTextFormat = new TextFormat("Monaco", 12);
txt.text = "enter text"; 
txt.addEventListener(MouseEvent.MOUSE_DOWN, onDown);
function onDown(evt:MouseEvent):void{
    txt.text = "";
    txt.removeEventListener(MouseEvent.MOUSE_DOWN, onDown);
}

This snippet is a mini code editor that allows the user to write javascript into a textfield - the javascript is then run using external interface. Optionally the javascript code can populate two arrays (plot and colors). If these arrays are populated flash, will render the data in each array using the Graphics class.

Have a look at the demo:

If you do something nice with this... post your javascript snippet as a comment and I'll add it to the JS Sketch page...

Also posted in Graphics, Math, dynamic, functions | Tagged actionscript, as3, flash, javascript | Leave a comment

ActionScript Eval (well, not really)

By Zevan | October 3, 2009

CLICK HERE TO COPY

Actionscript:

var txt:TextField = TextField(addChild(new TextField()));
txt.autoSize = TextFieldAutoSize.LEFT;
 
var myVar:Number = 100;
// works as an expression parser
txt.text = js("return (" + myVar + " * 2 + 10) / 2");
txt.appendText("\n\n");
 
// parses javascript
txt.appendText(js("var a = []; for (var i = 0; i<10; i++){ a.push(i) } return a;"));
 
function js( data:String ):*{
   var res:*= ExternalInterface.call("function(){" + data + "}");
   return (res == null) ? "null" : res;
}

This one made my day - CAN'T believe I never thought of it before... haven't done any speed tests yet... but it shows how to use ExternalInterface.call to parse math expressions and javascript code. This will only work when the swf is shown in an html page of course... so if your in flash cmd+f12...

I got the idea from this code snippet... which actually has an error in it... the decode() function should not return void... I found that snippet thanks to this tweet by makc3d.

Also posted in Math, functions, misc, string manipulation, strings | Tagged actionscript, flash, javascript | Leave a comment

base32 Twitter Coordinates

By Zevan | August 5, 2009

CLICK HERE TO COPY

Actionscript:

[SWF(width = 800, height=700, frameRate=30, backgroundColor=0x000000)]
var canvas:BitmapData = new BitmapData(1000,800,false, 0x000000);
addChild(new Bitmap(canvas));
 
var coords:String ="";
var index:int = 0;
addEventListener(Event.ENTER_FRAME, onLoop);
 
var s:Shape = new Shape();
with (s.graphics) beginFill(0xFFFFFF, 0.3), drawCircle(4,4,4)
var brush:BitmapData = new BitmapData(10,10, true, 0x00000000);
brush.draw(s);
 
var pnt:Point = new Point();
function onLoop(evt:Event):void {
     if (coords.length> 0){
         for (var i:int = 0; i<100;i++){
             if (index <coords.length){
                 pnt.x+= 0.2;
                 pnt.y = parseInt(coords.substr(index,3), 32) / 2;
                 index+=3;
                 canvas.copyPixels(brush, brush.rect, pnt, null, null, true);
             }else{
                break;
                removeEventListener(Event.ENTER_FRAME, onLoop);
             }
         }
     }
}
 
var loader:URLLoader = new URLLoader();
var req:URLRequest = new URLRequest("http://search.twitter.com/search.atom");
var vars:URLVariables = new URLVariables();
vars.q = "as3, flash";
vars.rpp = "100";
vars.page = 1;
vars.lang = "en";
req.data = vars;
req.method = URLRequestMethod.POST;
loader.load(req);
loader.addEventListener(Event.COMPLETE, onLoaded);
function onLoaded(evt:Event):void{
    var searchData:XML = new XML(loader.data);
    var atom:Namespace = searchData.namespace("");
    default xml namespace = atom;
    var titles:String = "";
    for each(var entry:XML in searchData.entry){
        titles += entry.title.toString();
    }
    var index:int = 0;
    var words:Array = titles.split(" ");
    words.sort();
    for (var i:int = 0; i<words.length; i++){
        if (words[i].match(/RT|\@|\#|http/g).length == 0){
            var word:String = words[i].replace(/[\W]/g, "");
            if (word.length> 1){
                coords += word + " ";
            }
        }
    }
}

This snippet does a twitter search and sorts the results alphabetically. It then reads through the results 3 characters at a time - each set of 3 characters is converted to base32 and then used a y coordinate on a plot.

In order for the swf to be worth looking at, I think I'd need to add an input field. I may do that later... but for now here are a few stills:

Also posted in BitmapData, string manipulation, strings | Tagged actionscript, as3, flash, twitter | 2 Comments

Twitter Texture Alphabet

By Zevan | August 4, 2009

CLICK HERE TO COPY

Actionscript:

[SWF(width = 1000, height=800, frameRate=60)]
 
// if you don't have flex you'll need to embed this font in your library
[Embed(source="/Library/Fonts/Verdana.ttf", fontFamily="Verdana")]
var Verdana:Class;
 
var canvas:BitmapData = new BitmapData(1000,800,false, 0xFFFFFF);
addChild(new Bitmap(canvas));
var overlay:BitmapData = new BitmapData(1000,800,true, 0x01FFFFFF);
 
 
var txt:TextField = TextField(addChild(new TextField()));
with (txt){
    defaultTextFormat = new TextFormat("Verdana", 10);
    embedFonts = true;
    width = stage.stageWidth-20;
    height = stage.stageHeight-20;
    multiline = true;
    wordWrap = true;
    text ="";
    textColor = 0x444444;
    selectable = false;
    x = y = 10;
    text = "loading...";
}
 
 
var selectWords:Array = [];
var currFirstLetter:String="";
var prevFirstLetter:String="";
var index:int = 0;
var anchorX:Number = 0, anchorY:Number = 0, theta:Number, radius:Number;
addEventListener(Event.ENTER_FRAME, onLoop);
function onLoop(evt:Event):void {
     canvas.copyPixels(overlay, overlay.rect, new Point(0,0), null, null, true);
     var leng:int = selectWords.length;
     if (leng> 0){
         var word:String = selectWords[index % leng];
         trace(word);
         currFirstLetter = word.charAt(0);
         if (currFirstLetter != prevFirstLetter){
             anchorX = Math.random() * (stage.stageWidth - 200) + 100
             anchorY = Math.random() * (stage.stageHeight - 200) + 100;
             theta = Math.random() * Math.PI * 2;
             radius = 50 + Math.random() * 100;
             txt.textColor = [0,0xFFFFFF,0xCCCCCC,0x666666][int(Math.random()*4)];
         }else{
             txt.x = anchorX + radius * Math.cos(theta);
             txt.y = anchorY + radius * Math.sin(theta);
             theta += Math.random() * .1;
             radius += 3;
             txt.scaleX = txt.scaleY = 1 + Math.random();
             if (int(Math.random()*30) == 1) txt.scaleX = txt.scaleY = 1 + Math.random()*10;
             txt.rotation = theta / Math.PI * 180;
             txt.text = word;
             canvas.draw(txt, txt.transform.matrix);
         }
         prevFirstLetter = currFirstLetter;
         index++;
     }
}
 
var loader:URLLoader = new URLLoader();
var req:URLRequest = new URLRequest("http://search.twitter.com/search.atom");
var vars:URLVariables = new URLVariables();
vars.q = "alphabet";
// results per page
vars.rpp = "100";
vars.page = 1;
vars.lang = "en";
 
req.data = vars;
req.method = URLRequestMethod.POST;
loader.load(req);
loader.addEventListener(Event.COMPLETE, onLoaded);                                  
function onLoaded(evt:Event):void{
    var searchData:XML = new XML(loader.data);
    var atom:Namespace = searchData.namespace("");
    default xml namespace = atom;
    var titles:String = "";
    for each(var entry:XML in searchData.entry){
        titles += entry.title.toString();
    }
    var index:int = 0;
    var words:Array = titles.split(" ");
    for (var i:int = 0; i<words.length; i++){
        // exclude a few things
        if (words[i].match(/RT|\@|\#|http/g).length == 0){
            selectWords[index++] = words[i].replace(/\s|\r|\n|\"/g, "");
        }
    }
    selectWords.sort();
    txt.text =""
        removeChild(txt);
}

This snippet draws a texture using a twitter search for the word "alphabet". The results are arranged alphabetically and used to draw a texture.

Have a look at the swf:

Also posted in BitmapData, string manipulation, strings | Tagged actionscript, as3, flash, twitter | 2 Comments

Category Archives: external data

JS Sketch Experiment

ActionScript Eval (well, not really)

base32 Twitter Coordinates

Twitter Texture Alphabet

Search

Pages

Recent Posts

Categories

Archives

RSS Feeds