Monthly Archives: September 2009

QuickBox2D addTimeStepSequence() Preview

By Zevan | September 11, 2009

Actionscript:

import com.actionsnippet.qbox.*;
 
[SWF(width = 800, height = 600, backgroundColor = 0xFFFFFF, frameRate=60)]
 
// hide everything for 300 ms
visible = false;
setTimeout(function():void{ visible = true}, 300);
 
var canvas:MovieClip = MovieClip(addChild(new MovieClip()));
 
var sim:QuickBox2D = new QuickBox2D(canvas, {debug:true});
 
sim.setDefault({fillColor:0x666666, lineAlpha:0})
sim.createStageWalls();
 
var boxA:QuickObject = makeLever(6 , 17.5, 9, "right", 0.7);
var circleA:QuickObject = sim.addCircle({x:2, y:3, radius:0.5, mass:4});
sim.addBox({x:15, y:12, width:2, height:0.5, density:0})
var circleB:QuickObject = sim.addCircle({x:16, y:11, radius:0.5, mass:4, friction:0.2, fillColor:0});
sim.addBox({x:20.5, y:12, width:2, height:0.3, angle:-0.6, restitution:4.6, density:0})
var boxB:QuickObject = makeLever(20 , 17.5, 8, "right", 1);
sim.addBox({x:9, y:9, width:2, height:0.5, density:0});
var circleC:QuickObject = sim.addCircle({x:9, y:9, radius:0.5, mass:4, friction:0.2, fillColor:0});
sim.addBox({x:7, y:12, width:2, height:0.5, angle:-0.3, density:0, restitution:2});
sim.addBox({x:3, y:7, width:2, height:0.5, angle:Math.PI/2 - 0.22, density:0, restitution:3});
sim.addBox({x:13, y:15, width:2, height:0.5, density:0, angle:0.3, restitution:1});
sim.addBox({x:25.5, y:7, width:2, height:0.3, angle:-0.2, restitution:0.5, density:0})
sim.addBox({x:26, y:10, width:1, height:1, density:0,restitution:0.3});
sim.addBox({x:25, y:19, width:2, height:0.5, density:0, restitution:3.5, angle:-0.99});
sim.addBox({x:1, y:17, width:0.3, height:2, density:0, angle:-0.15, restitution:0.999});
sim.addBox({x:0.7, y:11, width:0.3, height:2, density:0, angle:-0.19, restitution:20})
sim.addBox({x:0.4, y:11.5, width:1, height:0.3, density:0})
 
function makeLever(xp:Number, yp:Number, boxWidth:Number, dir:String, off:Number=0, hasBox:Boolean=true):QuickObject{
    var angle:Number, xpos:Number, weight:QuickObject
    if (dir == "right"){
        angle = 0.43;
        xpos = xp + boxWidth / 2 - off;
    }else{
        angle = -0.43;
        xpos = xp - boxWidth / 2 + off;
    }
    if (hasBox){
      weight = sim.addBox({x:xpos , y:yp, width:0.5, height:0.5, angle:angle, fillColor:0});
    }
    var plank:QuickObject = sim.addBox({x:xp, y:yp, width:boxWidth, height:0.5, angle:angle});
    var fulcrum:QuickObject = sim.addPoly({x:xp, y:yp, verts:[[0,0, 1,2, -1,2]], density:0})
    sim.addJoint({type:"revolute", a:plank.body, b:fulcrum.body, collideConnected:false});
    return weight;
}
 
sim.start();
 
// new feature, calls a function after a specific number of box2D timeSteps
sim.addTimeStepSequence({time:70, callback:cam, args:[boxA]}, 
                        {time:150, callback:cam, args:[circleB]},
                        {time:200, callback:cam, args:[boxB, 1.3]},
                        {time:580, callback:cam, args:[circleC]},
                        {time:700, callback:cam, args:[circleC, 1.1]},
                        {time:810, callback:cam, args:[boxB, 1.4]},
                        {time:870, callback:cam, args:[boxB, 3]},
                        {time:890, callback:cam, args:[boxB, 1.1]},
                        {time:1200,callback:cam, args:[boxB, 1]});
 
// set values for matrix pan and zoom
function cam(quickObj:QuickObject, scale:Number=-1):void{
    currQuick = quickObj;
    if (scale != -1){
        scaleDest = scale;
    }
}                                 
                
// matrix pan and zoom
var scale:Number = 1;
var scaleDest:Number = 1.2;
var down:Boolean = false;
var dx:Number = 0, dy:Number = 0, time:Number = 0;
var currQuick:QuickObject = circleA;
addEventListener(Event.ENTER_FRAME, onLoop);
function onLoop(evt:Event):void {
   scale += (scaleDest - scale) / 8; 
   dx += (currQuick.x*30 - dx) / 8;
   dy += (currQuick.y*30 - dy) / 8;
   // matrix zoom/pan
    var m:Matrix = canvas.transform.matrix;
   m.identity();
   m.translate(-dx,-dy);
   m.scale(scale, scale);
   m.translate(dx,dy);
   canvas.transform.matrix = m;
}

This is a preview of an upcoming feature for the QuickBox2D 1.0 release. It shows how addTimeStepSequence() is going to work. QuickBox2D 1.0 will have an internal timer counting the number of world steps that Box2D has taken. This is really useful for sequencing in conjunction with QuickBox2D's default FRIM (framerate independent motion).

This snippet uses addTimeStepSequence() to move a 2D camera around the simulation (from yesterdays post) - the camera pans and zooms... If you'd like to use addTimeStepSequence() simply replace your QuickBox2D.as file with this updated one:

I plan to release QuickBox2D 1.0 on monday - so I didn't think it made sense to do alpha 110 just for this one change...

Have a look at the swf....

Posted in Box2D, QuickBox2D, motion | Tagged actionscript, as3, Box2D, flash | 1 Comment

QuickBox2D Vaguely Goldberg-esque

By Zevan | September 10, 2009

CLICK HERE TO COPY

Actionscript:

import com.actionsnippet.qbox.*;
import Box2D.Common.Math.*;
import Box2D.Collision.Shapes.*;
 
[SWF(width = 800, height = 600, backgroundColor = 0xFFFFFF, frameRate=60)]
 
// hide everything for 300 ms
visible = false;
setTimeout(function():void{ visible = true}, 300);
 
var sim:QuickBox2D = new QuickBox2D(this, {debug:false});
 
sim.setDefault({fillColor:0x666666, lineAlpha:0})
sim.createStageWalls();
 
makeLever(6 , 17.5, 9, "right", 0.7);
 
var circleA:QuickObject = sim.addCircle({x:2, y:3, radius:0.5, mass:4});
 
sim.addBox({x:15, y:12, width:2, height:0.5, density:0})
 
sim.addCircle({x:16, y:11, radius:0.5, mass:4, friction:0.2, fillColor:0});
 
sim.addBox({x:20.5, y:12, width:2, height:0.3, angle:-0.6, restitution:4.6, density:0})
 
makeLever(20 , 17.5, 8, "right", 1);
 
sim.addBox({x:9, y:9, width:2, height:0.5, density:0});
 
sim.addCircle({x:9, y:9, radius:0.5, mass:4, friction:0.2, fillColor:0});
 
sim.addBox({x:7, y:12, width:2, height:0.5, angle:-0.3, density:0, restitution:2});
 
sim.addBox({x:3, y:7, width:2, height:0.5, angle:Math.PI/2 - 0.22, density:0, restitution:3});
 
sim.addBox({x:13, y:15, width:2, height:0.5, density:0, angle:0.3, restitution:1});
 
sim.addBox({x:25.5, y:7, width:2, height:0.3, angle:-0.2, restitution:0.5, density:0})
 
sim.addBox({x:26, y:10, width:1, height:1, density:0,restitution:0.3});
 
sim.addBox({x:25, y:19, width:2, height:0.5, density:0, restitution:3.5, angle:-0.99});
 
sim.addBox({x:1, y:17, width:0.3, height:2, density:0, angle:-0.15, restitution:0.999});
 
sim.addBox({x:0.7, y:11, width:0.3, height:2, density:0, angle:-0.19, restitution:20})
 
sim.addBox({x:0.4, y:11.5, width:1, height:0.3, density:0})
 
function makeLever(xp:Number, yp:Number, boxWidth:Number, dir:String, off:Number=0, hasBox:Boolean=true):QuickObject{
    var angle:Number, xpos:Number, weight:QuickObject
    if (dir == "right"){
        angle = 0.43;
        xpos = xp + boxWidth / 2 - off;
    }else{
        angle = -0.43;
        xpos = xp - boxWidth / 2 + off;
    }
    
    if (hasBox){
      weight = sim.addBox({x:xpos , y:yp, width:0.5, height:0.5, angle:angle, fillColor:0});
    }
 
    var plank:QuickObject = sim.addBox({x:xp, y:yp, width:boxWidth, height:0.5, angle:angle});
    var fulcrum:QuickObject = sim.addPoly({x:xp, y:yp, verts:[[0,0, 1,2, -1,2]], density:0})
    sim.addJoint({type:"revolute", a:plank.body, b:fulcrum.body, collideConnected:false});
    return weight;
}
 
sim.start();

Just playing around with QuickBox2D and brainstorming about a few features for the first non-alpha release. If you have any feature suggestions, please feel free to leave them in the comments of this post (see the end of this post for a list features to come in QuickBox2D 1.0).

Have a look at the swf...

Upcoming Features for QuickBox2D
Simplified collision detection - will hopefully be something like hitTest for QuickObject instances.

QuickBox2D.totalTimeSteps - variable that keeps track of how many times b2World.Step() was called - useful for simple sequencing.

QuickBox2D.addTimeStepEvent(callAt:Number, callback:Function) - calls a function when QuickBox2D.totalTimeSteps is equal to the callAt value.

QuickBox2D.stepEvent - an event dispatched every time b2World.Step() is called.

New Renderer [probably not for 1.0 release]
I've been toying with the idea of creating a new renderer for QuickBox2D. Currently all rigid bodies are DisplayObjects... this is great if you plan on skinning all your rigid bodies, but if you just have flat colors it is slower than debug draw - also, debug draw mode could be optimized a good deal. So I may create a simpler, faster renderer that draws to one Graphics instance (like debug draw mode) - but abides by QuickBox2D's simple rendering params like lineColor, fillColor, lineAlpha etc...

I also need to decide how to skin the rest of the joints, currently skins only work for distance joints...

Posted in Box2D, QuickBox2D, motion | Tagged actionscript, as3, Box2D, flash, QuickBox2D | 4 Comments

White Circles Black Circles

By Zevan | September 9, 2009

CLICK HERE TO COPY

Actionscript:

[SWF(backgroundColor=0xFFFFFF, width=500, height=500)]
 
var hsw:Number = stage.stageWidth / 2;
var hsh:Number = stage.stageHeight / 2;
var pointNum:int = 200;
var points3D:Vector.<Number> = new Vector.<Number>();
var points2D:Vector.<Number> = new Vector.<Number>();
var uvts:Vector.<Number> = new Vector.<Number>();
var sorted:Array = [];
var thickness:Vector.<Number> = new Vector.<Number>();
var radii:Vector.<Number> = new Vector.<Number>();
var colors:Vector.<uint> = new Vector.<uint>();
 
var pnt:Point = new Point();
var m:Matrix3D = new Matrix3D();
var v:Vector3D = new Vector3D();
 
for (var i:int = 0; i<pointNum; i++){
    v.x = Math.random()*1000-500;
    m.identity();
    m.appendRotation(Math.random()*360, Vector3D.X_AXIS);
    m.appendRotation(Math.random()*360, Vector3D.Y_AXIS);
    m.appendRotation(Math.random()*360, Vector3D.Z_AXIS);
    v = m.transformVector(v);
    points3D.push(v.x, v.y, v.z);
    points2D.push(0,0);
    uvts.push(0,0,0);
    sorted.push({});
    thickness.push(Math.random() * Math.random() * 50 + 4);
    radii.push(Math.random() * 100 + 10);
    colors.push([0xFFFFFF, 0x000000][int(Math.random()*2)]);
}
points3D.fixed = true;
points2D.fixed = true;
uvts.fixed = true;
thickness.fixed = true;
radii.fixed = true;
colors.fixed = true;x
var p:PerspectiveProjection = new PerspectiveProjection();
var proj:Matrix3D = p.toMatrix3D();
var dx:Number = 0, dy:Number = 0;
addEventListener(Event.ENTER_FRAME, onLoop);
function onLoop(evt:Event):void {
    var i:int, j:int;
    dx += (mouseX - dx) / 4;
    dy += (mouseY - dy) / 4;
    m.identity();
    m.appendRotation(dx, Vector3D.Y_AXIS);
    m.appendRotation(dy, Vector3D.X_AXIS);
    m.appendTranslation(0, 0, 1000);
    m.append(proj);
    Utils3D.projectVectors(m, points3D, points2D, uvts);
    for (i = 0, j = 0; i<points2D.length; i+=2, j++){
        sorted[j].x = points2D[i] + hsw;
        sorted[j].y = points2D[i + 1] + hsh;
        sorted[j].z = uvts[j * 3 + 2];
        sorted[j].color = colors[j];
        sorted[j].radius = radii[j];
        sorted[j].thickness = thickness[j];
    }
    sorted.sortOn("z", Array.NUMERIC);
    graphics.clear();
    for(i = 0; i<sorted.length; i++){
        var element:Object = sorted[i];
        var zpos:Number = element.z * 18000;
        graphics.lineStyle(element.thickness, element.color);
        graphics.drawCircle(element.x, element.y, zpos + element.radius);
        graphics.endFill();
    }
}

Was just looking at the stills from yesterdays post and noticing how much I actually like the way they looked. Really simple, just black and white cirlces - reminded me a bit of this flash experiment by Jared Tarbell (from 2002).

So I popped the same kind of black and white circles into the z-sorting 3D snippet I've been using recently and came up with this...

Have a look at the swf...

Posted in Uncategorized | Tagged actionscript, as3, flash | Leave a comment

Matrix Zoom and Pan

By Zevan | September 8, 2009

CLICK HERE TO COPY

Actionscript:

[SWF(width=600, height=600, frameRate=30)]
var sw:Number = stage.stageWidth;
var sh:Number = stage.stageHeight;
 
var s:Shape = Shape(addChild(new Shape()));
 
var scale:Number = 1;
var scaleDest:Number = 1;
var down:Boolean = false;
var dx:Number = 0, dy:Number = 0, time:Number = 0;
 
buttonMode = true;
 
addInstructions();
vectorTexture();
 
stage.addEventListener(MouseEvent.MOUSE_DOWN, onDown);
stage.addEventListener(MouseEvent.MOUSE_UP, onUp);
addEventListener(Event.ENTER_FRAME, onLoop);
 
function addInstructions():void{
    var instruct:Sprite = Sprite(addChild(new Sprite()));
    with (instruct.graphics) beginFill(0x666666), drawRect(0,0,270, 30);
    instruct.x = instruct.y = 20;
    var txt:TextField = TextField(instruct.addChild(new TextField()));
    txt.defaultTextFormat = new TextFormat("Verdana", 11);
    txt.x = txt.y = 5;
    txt.selectable = false;
    with (txt) textColor = 0xFFFFFF, autoSize = "left", text = "Click and hold to zoom, move mouse to pan";
}
 
function vectorTexture():void{
    var cols:Vector.<uint> = Vector.<uint>([0xFFFFFF, 0x000000]);
    var rnd:Vector.<Number> = new Vector.<Number>(6, true);
    
    for(var i:int = 0 ; i<50; i++){
        with(s.graphics){
            lineStyle(Math.random() * 50 + 2, cols[int(Math.random()*cols.length)]);
            drawCircle(Math.random() * sw, Math.random() * sh, 10 + Math.random() * Math.random() * 400);
        }
    }
    s.graphics.lineStyle(20, 0xCCCCCC);
    s.graphics.drawRect(0, 0,sw, sh);
}
 
function onDown(evt:MouseEvent):void{ down = true; }
function onUp(evt:MouseEvent):void{ down = false; }
function onLoop(evt:Event):void {
   if (down){
     scaleDest *= 1.05;  
     time = 0;
   }else{
     time++;
     // zoom out after 30 iterations
     if (time == 30){
         scaleDest = 1;  
     }
   }
   scale += (scaleDest - scale) / 4;
   if (scale> 10) scale = scaleDest = 10;
   
   dx += (mouseX - dx) / 4;
   dy += (mouseY - dy) / 4;
   if (dx <0) dx = 0;
   if (dy <0) dy = 0;
   if (dx> sw) dx = sw;
   if (dy> sh) dy = sh;
   
   // matrix zoom/pan
   var m:Matrix = s.transform.matrix;
   m.identity();
   m.translate(-dx,-dy);
   m.scale(scale, scale);
   m.translate(dx,dy);
   s.transform.matrix = m;
}

I haven't been by the computer much these last two weeks - been traveling. Going back to nyc tomorrow so I'll go back to posting once a day.

This snippet uses a transformation matrix to zoom in and pan a Sprite instance. For demo purposes I filled the sprite with a few circles - but you'd likely be using this with a vector image of a map, a floor plan or some other graphic that warrants zooming and panning.

Back around flash 7 (I think) before the Matrix class was introduced we used to have to use MovieClip nesting to achieve this effect.

Have a look at the swf...