Category Archives: external data

XML to ActionScript #3 (AsXML)

By Zevan | June 22, 2009

XML:

<code>
  <make reference="w" class="BasicView" args="stage.stageWidth, stage.stageHeight, false"/>
  <call method="addChild" args="w"/>
  
  <make reference="wireMat" class="WireframeMaterial" args="0x000000" />
  
  <make reference="sphere" class="Sphere" args="wireMat, 100" />
  
  <call method="w.scene.addChild" args="sphere" />
  
  <make reference="animation" class="Object">
    <set z="-500" rotationY="360"  rotationX="360" ease="Back.easeOut"/>
  </make>
  
  <call method="TweenLite.to" args="sphere, 3, animation" />
  
  <call method="setInterval" args="w.singleRender, 32" />
  
</code>

This snippet shows XML that the mini-library AsXML can read and run - in this case AsXML is set up to run with Papervision

A few days ago I had the idea to write some code that would run ActionScript based on XML. I spent some time getting rid of a few bugs and setting up some demos with TweenLite, Papervision and QuickBox2D. I wrapped everything up into a mini-library called AsXML.

Check out the demos here.

Download AsXML and demo files here.

AsXML Features:
1) call methods of the main timeline
2) read and write properties on the main timeline
3) instantiate classes on the main timeline
4) call methods on these classes
5) read and write properties on these classes
6) store references to return values from functions

Also posted in Box2D, Graphics, Math, QuickBox2D, XML, dynamic, instantiation, misc, motion, return values, string manipulation, strings | Tagged actionscript, as3, flash | 11 Comments

XML to ActionScript #2

By Zevan | June 20, 2009

CLICK HERE TO COPY

Actionscript:

var script:XML=<code>
  
   <make reference="blur" class="flash.filters.BlurFilter">
     <set blurX="10" blurY="10" />
   </make>
   
   <make reference="filts" class="Array">
     <call method="push">
       <arg reference="blur" />
     </call>
   </make>
   
   <make reference="mat" class="flash.geom.Matrix">
     <call method="rotate" args="1" />
     <set tx="100" ty="100" />
   </make>
   
   <make reference="box" class="flash.display.Sprite">
       <setRef filters="filts" transform.matrix="mat"/>
       <call method="graphics.beginFill" args="0x000000" />
       <call method="graphics.drawRect" args="-50,-50,100,100" />
   </make>
   
   <call method="addChild">
     <arg reference="box"/>
   </call>
   
   <make reference="tf" class="flash.text.TextFormat">
    <set font="_sans" size="12" color="0xFFFFFF" />
   </make>
  
   <make reference="txt" class="flash.text.TextField">
     <setRef defaultTextFormat="tf" />
     <set autoSize="center" text="XML to AS3" />
   </make>
  
   <make reference="circle" class="flash.display.Sprite">
       <set x="300" y="300" />
       <call method="graphics.beginFill" args="0xFF0000" />
       <call method="graphics.drawCircle" args="0,0,100" />
       <call method="addChild">
         <arg reference="txt" />
       </call>
   </make>
   
   <call method="addChild">
     <arg reference="circle"/>
   </call>
  
</code>
 
// parse and run
runCode(this, script);
 
function runCode(target:*, code:XML):void{
    var children:XMLList = code.children();
    for (var i:int = 0; i<children.length(); i++){
        var child:XML = children[i];
        var type:String = child.name();
        if (type == "call"){
            runMethod(target, child);
        }else if (type == "set"){
            setProp(target, child);
        }else if (type == "setRef"){
            setRefProp(target, child);
        }else if (type == "make"){
            makeInstance(child);
        }
    }
}
 
function makeInstance(code:XML):void{
    var ClassRef:Class = getDefinitionByName(code.@["class"]) as Class;
    // nothing can be passed to the class constructor
    // its not possible with function.apply
    var instance:* = this[code.@reference] = new ClassRef();
    runCode(instance, code);
}
 
// set a property to a reference
function setRefProp(target:*, code:XML):void{
    var attributes:XMLList = code.attributes(); 
    for (var i:int = 0; i<attributes.length(); i++){
        var prop:String = attributes[i].name();
        var o:Object = dotSyntax(target, prop, 1)
        if (prop.indexOf(".") != -1){
          o.obj[o.prop] = dotSyntax(this, attributes[i]);
        }else{
          o.obj[o.prop] = this[attributes[i]];
        }
    }
}
 
// set a property to a value such as a Number, Boolean, String etc...
function setProp(target:*, code:XML):void{
    var attributes:XMLList = code.attributes(); 
    for (var i:int = 0; i<attributes.length(); i++){
        var prop:String = attributes[i].name();
        var o:Object = dotSyntax(target, prop, 1)
        o.obj[o.prop] = valueType(attributes[i]);
    }
}
 
function runMethod(target:*, code:XML):void{
    var i:int = 0;
    // get a reference to the function
    var method:Function = dotSyntax(target, code.@method);
    // call the function if there are no arguments
    var attributeArgsLength:int = code.@args.toXMLString().length;
    var childArgsLength:int = code.arg.length()
    if (attributeArgsLength == 0 && childArgsLength == 0){
        method();
    }else{
     
     var args:Array;
     if (attributeArgsLength> 0){
         args = code.@args.toString().split(",");
     } else {
        args = []; 
     }
    
     for (i = 0; i<childArgsLength; i++){
          var val:String = code.arg[i].@value;
          if (val){
            args.push(val); 
          }
      }
      for (i = 0; i<args.length; i++){
          if (args[i] != ""){
            args[i] = valueType(args[i]); 
          }
      }
      for (i = 0; i<code.arg.length(); i++){
         var rs:String = code.arg[i].@reference;
         if (rs){
             args.push(dotSyntax(this, rs));  
         }
      }
     
      // run the function
      method.apply(null,args);
    }
}
 
// parse dot syntax and return the last property or method
function dotSyntax(target:*, str:String, offset:int = 0):*{
    var path:Array = str.split(".");
    var curr:* = target;
    for (var i:int = 0; i<path.length - offset; i++){
        curr = curr[path[i]]
    }
    if (offset != 0){
        return {obj:curr, prop:path[i]}
    }
    return curr;
}
 
function valueType(val:*):* {
    if (isNaN(Number(val))) {
           // remove leading and trailing white
           // remove "" around strings
           val = val.replace(/^s+|s+$/g,"").replace(/^"|"$/g,"");
           //  see if it's a boolean
           if (val == "true"){
               val = true;
           }else if (val == "false"){
               val = false
           }
    } else {
        val = Number(val);
    }
    return val;
}

WARNING: There area few small bugs in this snippet. If you'd like to use this, check out the AsXML mini-library

This is the next version of yesterdays snippet. As you can see it isn't really a snippet anymore... This code parses a specifically formatted xml file to allow the following features to be achieved from XML at runtime:

1) call methods of the main timeline
2) read and write properties on the main timeline
3) instantiate classes on the main timeline
4) call methods on these classes
5) read and write properties on these classes

By implement those five feature a great deal becomes possible. The above XML creates this somewhat crappy looking thing:

While that doesn't look like much, it's actually doing quite a bit... It has a BlurFilter, an Array (for the filters property), two Sprites, a TextFormat and a TextField. addChild() is called on the main timeline and on one of the sprites (to nest the TextField in the circle).

Uses For This

You could use this to create levels for a simple game.

You could generate this XML based on user input to create e-cards and mini-apps.

If you have a medium sized app you could use it to create a sort of advanced config file that helps to ease your pain as the client decides they need 10 subtly different versions of the app. Every time the client decides they need a subtly different version you'd just need to create a different config file. THIS is probably the thing that I'll be using it for - could be a huge time saver...

Uses With Libraries

This could be used with TweenLite and/or Papervision. You could just add a bunch of import statements to the timeline or to a dynamic document class. Then you'd be able to do some basic authoring from the XML. I think I'll post an example of this either tonight or tomorrow.

I did originally start writing this thinking about QuickBox2D - but I already have an editor for QuickBox2D that just needs some UI (currently its key controlled). So I don't really need it. The QuickBox2D editor generates an ActionScript file - which makes sense because usually you need to go in and manually do a bunch of logic that couldn't really be done easily with an editor. That said, this will work with Box2D or QuickBox2D as an XML format.

The Downside

The downside is that this is dynamic and is therefore untyped. All class instances created by reading the XML will be dynamically typed. For something where your only adding 10 classes this way, its no big deal - but for a game editor it could be a problem - at the very least there are interesting advanced techniques implemented in this snippet that could be repurposed for lots of different things.

More Examples

Tonight or tomorrow I'll upload a few examples - it would be fun to do a TweenLite/Papervision example... would also be good to show what I mean by an advanced config for a medium sized app.

Also posted in XML, dynamic, instantiation | Tagged actionscript, as3, flash | 2 Comments

XML to ActionScript

By Zevan | June 19, 2009

CLICK HERE TO COPY

Actionscript:

// this xml is inline but could easily be in an external file
var script:XML=<code>
 
  <!-- // call some methods of the main timeline graphics property -->
  <call method="graphics.beginFill" args="0xFF0000" />
    
  <call method="graphics.drawRect" args="0, 0">
     <!-- // use this to access properties of the main movie --> 
     <!-- // and use them as arguments -->
     <arg reference="stage.stageWidth" />
     <arg reference="stage.stageHeight" />
  </call>
  
  <call method="graphics.endFill" args=""/>
  
  <call method="graphics.beginFill" args="0x0000FF">
     <!-- //regular non-reference arguments can be passed like this -->
     <arg value="0.5" />
  </call>
  
  <call method="graphics.drawCircle" args="100,100,20" />
  
  <call method="customFunction" args="hello">
     <arg reference="root.loaderInfo.bytesTotal" />
  </call>
  
</code>
 
function customFunction(a:String, b:String):void{
    trace("I am a custom function called from xml");
    trace("Here is an argument: " + a);
    trace("Here is another argument, (total bytes of this swf): " + b);
}
 
// parse and run
runCode(script);
 
function runCode(code:XML):void{
    var children:XMLList = code.children();
    for (var i:int = 0; i<children.length(); i++){
        var child:XML = children[i];
        var type:String = child.name();
        if (type == "call"){
            runMethod(child);
        }
    }
}
 
function runMethod(code:XML):void{
    var i:int = 0;
    // get a reference to the function
    var method:Function = dotSyntax(code.@method);
    // call the function if there are no arguments
    if (code.@args.toXMLString().length == 0 && code.arg.length() == 0){
        method();
    }else{
     
     var args:Array = code.@args.split(",");
     var childArgsLength:int = code.arg.length()
     for (i = 0; i<childArgsLength; i++){
          // add another one with dot syntax
          var val:String = code.arg[i].@value;
          if (val){
            args.push(val); 
          }
      }
      for (i = 0; i<args.length; i++){
          if (args[i] != ""){
            args[i] = valueType(args[i]); 
          }
      }
      for (i = 0; i<code.arg.length(); i++){
         var rs:String = code.arg[i].@reference;
         if (rs){
             var ref:* = dotSyntax(rs);
             args.push(ref);  
         }
      }
      // run the function
      method.apply(null,args);
    }
}
 
// parse dot syntax and return the last property or method
function dotSyntax(str:String):*{
    var path:Array = str.split(".");
    var curr:* = this;
    for (var i:int = 0; i<path.length; i++){
        curr = curr[path[i]]
    }
    return curr;
}
 
function valueType(val:*):* {
    if (isNaN(Number(val))) {
           // remove leading and trailing white
           // remove "" around strings
           val = val.replace(/^s+|s+$/g,"").replace(/^"|"$/g,"");
           //  see if it's a boolean
           if (val == "true"){
               val = true;
           }else if (val == "false"){
               val = false
           }
    } else {
        val = Number(val);
    }
    return val;
}

WARNING: There area few small bugs in this snippet. If you'd like to use this, check out the AsXML mini-library

A few days ago I had the idea to write some code that would parse ActionScript from XML. The features that I realized would be possible are:

So this morning I wrote the first part. This snippet has the ability to read an XML file and call methods accordingly. It also has the ability to read properties of the main timeline and pass them to these methods.

The XML in this snippet draws a box using the stageWidth and stageHeight. It draws a transparent circle and then calls a custom function. The custom function gets passed the root.loaderInfo.bytesTotal property.

I've done something similar a few times where I specifically targeted the Graphics API. This takes that to the next level by potentially working with any ActionScript classes (excluding Vector maybe... need to think about that).

I'll post another version with more features tomorrow. At the very least it will have class instantiation.

Also posted in XML, dynamic, string manipulation | Tagged actionscript, as3, flash | 6 Comments

Graphics Class Methods in XML

By Zevan | February 6, 2009

CLICK HERE TO COPY

Actionscript:

// for simplicity I left this XML inline, this will work exactly the same if it were external
var program:XML=<body>
                <draw>
                  <![CDATA[
                   beginFill(0xFF0000);
                   drawCircle(100,100,50);
                   endFill();
                   lineStyle(0, 0x666666);
                   moveTo(100, 100);
                   lineTo(200, 200);
                   moveTo(300, 200);
                   curveTo(350, 300, 400, 200);
                   lineStyle(0, 0x0000FF);
                   drawRect(200, 50,100,100) ;
                    ]]>
                </draw>
</body>;
 
// parse and run the Graphics class commands from the XML
render(parseFunctions(program.draw.toString()));
 
function parseFunctions(dat:String):Array{
    var a:Array = dat.split(";") ;
    for (var i:int = 0; i<a.length-1; i++){
        a[i] = a[i].split(/\(\)|\(|\)/g);
        var f:String = a[i][0] = a[i][0].replace(/\s/g,"");
        a[i] = a[i].splice(0, a[i].length - 1);
        if (a[i].length> 1){
         a[i] = a[i][1].split(",");
         a[i].unshift(f);
        }
    }
    return a.splice(0,a.length - 1);
}
function render(p:Array):void {
    for (var i:int = 0; i<p.length; i++) {
        graphics[p[i][0]].apply(graphics,p[i].splice(1));
    }
}

The above code builds on yesterdays post by showing how one could potentially store graphics class method calls in XML using a few regular expressions and Function.apply().

The parseFunctions() function reads through the CDATA string and formats it in a 2D array that looks like this:

CLICK HERE TO COPY

Actionscript:

[[beginFill, 0xFF0000], [drawCircle, 100, 100, 50], etc...]

The render() function reads through this 2D array, using the first value of each nested array as the function and the remaining values as arguments...

As is this won't really work with most of the new fp10 graphics methods...

Also posted in Graphics, XML, dynamic, functions, string manipulation, strings | Tagged actionscript, flash | Leave a comment

Search
ActionSnippet is on Twitter
Pages
- about
- all posts
- QuickBox2D
- warning
Recent Posts
Categories
- 3D
- Announcements
- arrays
- associative arrays
- bezier
- binary
- BitmapData
- Box2D
- color
- Data Structures
- Dictionary
- display list
- DisplayObject
- dynamic
- es6
- Events
- external data
- functions
- glsl
- Graphics
- graphics algorithms
- html5
- instantiation
- javascript
- keys
- links
- Loader
- Math
- matrix
- misc
- motion
- MovieClip
- Number
- Object
- one-liners
- OOP
- Operators
- pixel manipulation
- projects
- properties
- QuickBox2D
- Quiz
- random
- return values
- setPixel
- sortOn
- string manipulation
- strings
- svg
- TextField
- timeline
- UI
- Uncategorized
- variables
- Vector
- Video
- webgl
- XML
Archives
- November 2024
- July 2024
- June 2024
- December 2018
- October 2018
- August 2018
- July 2018
- July 2012
- June 2012
- August 2011
- January 2011
- July 2010
- June 2010
- May 2010
- April 2010
- March 2010
- February 2010
- January 2010
- December 2009
- November 2009
- October 2009
- September 2009
- August 2009
- July 2009
- June 2009
- May 2009
- April 2009
- March 2009
- February 2009
- January 2009
- December 2008
- November 2008
- October 2008
- 0

RSS Feeds
- All posts
- All comments

Category Archives: external data

XML to ActionScript #3 (AsXML)

XML to ActionScript #2

Uses For This

Uses With Libraries

The Downside

More Examples

XML to ActionScript

Graphics Class Methods in XML

Search

Pages

Recent Posts

Categories

Archives

RSS Feeds