import com.actionsnippet.qbox.*;
import Box2D.Dynamics.*;
import Box2D.Collision.Shapes.*;
 
[SWF(width = 800, height = 600, backgroundColor = 0x222222, frameRate=60)]

var sim:QuickBox2D = new QuickBox2D(this, {debug:false});

var box:QuickObject = sim.addBox({x:12, y:16, width:3, height:3, density:0 , groupIndex:-1});
var circle:QuickObject = sim.addCircle({x:5, y:3, radius:0.5, groupIndex:-1});

// add another box to show that Box2D is still working
var littleBox:QuickObject = sim.addBox({x:12, y:3, width:1, height:1});

sim.createStageWalls();

sim.start();
sim.mouseDrag();

var filter:b2ContactFilter = new QuickContactFilter();
QuickContactFilter(filter).addGroupIndexCallback(onGroupNeg1, -1);

function onGroupNeg1(a:b2Shape, b:b2Shape):void{
	//trace("group index -1 had a collision");
	box.userData.alpha = 0.5;
	setTimeout(function():void{ box.userData.alpha = 1 }, 200);
}

sim.w.SetContactFilter(filter);

This snippet answers a question from a recent comment. The question was basically: “Can you detect a collision between two rigid bodies that have the same negative groupIndex?”. When you give QuickObjects a negative groupIndex it means that they will not collide with one another. So by default Box2D contacts will not be triggered when these two rigid bodies overlap. In order to determine if these rigid bodies overlap you need to implement a custom b2ContactFilter class. This may sound confusing but its actually very easy. You can take a look at the custom b2ContactFilter class used in this snippet here: QuickContactFilter.as – It’s important to note that QuickContactFilter.as is not yet part of QuickBox2D, so if you want to run this snippet you’ll need to download the .as file.

You can check out the swf here…

import com.actionsnippet.qbox.*;
import Box2D.Common.Math.*;

[SWF(width = 800, height = 600, backgroundColor = 0x222222, frameRate=60)]

var sim:QuickBox2D = new QuickBox2D(this, {debug:false});

sim.createStageWalls();

var cup:QuickObject = sim.addPoly({x:3, y:13, wireframe:false, density:0, 
								   points:[0,0, .5, 0, .5,3,  2,3,  2,0,  2.5,0, 2.5, 3.5, 0, 3.5, 0,0]});
var deleter:QuickObject = sim.addBox({x:4.251, y: 15.9, width:1.5, height:0.25, fillColor:0xFF0000});

// use a distance joint instead of a group since isCurrentContact 
// uses the QuickObject.body property
sim.addJoint({a:cup.body, b:deleter.body, x1:deleter.x, y1:deleter.y+0.5});

var circles:Array = [];
for (var i:int = 0; i<10; i++){
	circles[i] = sim.addCircle({x:8 + i, y:5, radius:0.5});
}
var boxes:Array = [];
for (i = 0; i<10; i++){
	boxes[i] = sim.addBox({x:8.5 + i, y:10, width:0.5, height:0.5});
}

sim.start();
sim.mouseDrag();

var shootVec:b2Vec2 = new b2Vec2(4, -30);

// when circles are dropped in the cup they are destroyed
// when boxes are droppped in the cup their linear velocity is altered
var contacts:QuickContacts = sim.addContactListener();
contacts.addEventListener(QuickContacts.ADD, onAdd);
function onAdd(evt:Event):void{
	for (var i:int = 0; i<circles.length; i++){
		var circ:QuickObject = circles[i];
		if (contacts.isCurrentContact(circ, deleter)){
			// it's ok to destroy QuickObject here because they are only actually
			// destroyed after the timeStep has finished at the end of QuickBox2D's 
			// internal loop
			circ.destroy();
		}
	 } 
	 for (i = 0; i<boxes.length; i++){
		var box:QuickObject = boxes[i];
		if (contacts.isCurrentContact(box, deleter)){
			box.body.SetLinearVelocity(shootVec);
		}
	 }
}

Note: This snippet requires QuickBox2D 1.0 or greater

Here is another example of using QuickBox2D style contacts. In this example there is a cup with a small red box inside of it. When circles are placed inside the cup they are destroyed. When boxes are placed inside the cup they are shot upward.

Have a look at the swf…

A Note About Creation and Destruction

It’s worth noting that in Box2D your not supposed to destroy or create rigid bodies within the listener function for any contact events. QuickBox2D gets around this restriction by flagging the rigid body for destruction and destroying it at the end of QuickBox2D’s internal loop. This is not the case with creation of rigid bodies – if you attempt to create a rigid body within one of these listener functions you will get an error. See QuickBox2D Contacts Part 1 for an example of creating rigid bodies when there is a collision.

import com.actionsnippet.qbox.*;

[SWF(width = 800, height = 600, backgroundColor = 0x000000, frameRate=60)]

var sim:QuickBox2D = new QuickBox2D(this);

sim.createStageWalls();

var boxA:QuickObject = sim.addBox({x:3, y:3, width:2, height:2});
var boxB:QuickObject = sim.addBox({x:3, y:6, width:2, height:2});

// add a few extra circles to show that there are other contacts
// occuring
for (var i:int = 0; i<10; i++){
	sim.addCircle({x:5 + i, y:4, radius:0.1 + Math.random()});
}

sim.start();
sim.mouseDrag();

// when boxA touches boxB change their alpha values to 50%
var contacts:QuickContacts = sim.addContactListener();
contacts.addEventListener(QuickContacts.ADD, onAdd);
contacts.addEventListener(QuickContacts.PERSIST, onPersist);
contacts.addEventListener(QuickContacts.REMOVE, onRemove);
function onAdd(evt:Event):void{
	if(contacts.isCurrentContact(boxA, boxB)){
		boxA.userData.alpha = 0.5;
		boxB.userData.alpha = 0.5;
	}
}
function onPersist(evt:Event):void{
	if(contacts.isCurrentContact(boxA, boxB)){
		boxA.userData.alpha = 0.5;
		boxB.userData.alpha = 0.5;
	}
}
function onRemove(evt:Event):void{
	if(contacts.isCurrentContact(boxA, boxB)){
		boxA.userData.alpha = 1;
		boxB.userData.alpha = 1;
	}
}

Note: This snippet requires QuickBox2D 1.0 or greater

This is another example showing how to make use of QuickBox2D contacts. In this example three contact events are used ADD, PERSIST and REMOVE. When the two boxes are touching their alpha values are set to 50% – otherwise their alpha values are at 100%.

Have a look at the swf…

A Little Detail About the Events

The ADD event is dispatched when a new b2ContactPoint is generated. The PERSIST event is dispatched as long as the b2ContactPoint exists for more than one timeStep – and from what I can tell, is dispatched until the rigid bodies it is associated with go to sleep. The REMOVE event is called when the b2ContactPoint is removed, meaning the rigid bodies that caused the creating of the b2ContactPoint are no longer touching.

You need to be careful with the code that you place inside the listener functions for these events. The reason being that these events are called many many times for every contact point in the simulation.

import com.actionsnippet.qbox.*;
import Box2D.Common.Math.*;

[SWF(width = 800, height = 600, backgroundColor = 0x000000, frameRate=60)]

var sim:QuickBox2D = new QuickBox2D(this, {debug:false, frim:true});

sim.createStageWalls();

var boxA:QuickObject = sim.addBox({x:3, y:3, width:2, height:2, fillColor:0xFF0000});
var boxB:QuickObject = sim.addBox({x:3, y:6, width:2, height:2, fillColor:0xFF0000});

sim.start();
sim.mouseDrag();

// when boxA touches boxB a circle QuickObject is created
var contacts:QuickContacts = sim.addContactListener();
// listen for contact points being added
contacts.addEventListener(QuickContacts.ADD, onAdd);
function onAdd(evt:Event):void{
	// see if this contact event is associated with boxA and boxB
	if(contacts.isCurrentContact(boxA, boxB)){
		// get the location of the collision in world space
		var loc:b2Vec2 = contacts.currentPoint.position;
		// you cannot create new QuickObjects inside this listener function
		// so we just give a 5 ms delay
		setTimeout(sim.addCircle, 5, {x:loc.x, y:loc.y});
	}
}

Note: This snippet requires QuickBox2D 1.0 or greater

I’ve created a few simple examples to show how to use QuickBox2D contact listeners. This is the first one. When two boxes collide circles are added to the simulation at the point of collision.

Have a look at the swf…

QuickBox2D 1.0 is ready. It contains a bunch of small bug fixes and a few new features that I’ll be demoing in the next few posts. The main new features relate to collision detection and simple event sequencing.

Go download it from here…

I also spent some time updating the docs…. everything is documented… I may add additional documentation text over the next few days…

A detailed tutorial for QuickBox2D is also in the works…

[EDIT]

Also, if you find any bugs send me an e-mail (see about page for e-mail)… if there are any bugs left I’d like to fix the asap…. You can also feel free to e-mail any API suggestions…