Latest snippets

// best thing about this are the random seeds
var s1:Number= 0xFFFFFF;
var s2:Number = 0xCCCCCC;
var s3:Number= 0xFF00FF;

// saw this algorithm on this somewhat annoying thread:
// http://www.reddit.com/r/programming/comments/7yjlc/why_you_should_never_use_rand_plus_alternative/
// additional googling brought me to this: http://wakaba.c3.cx/soc/kareha.pl/1100499906/
// and finally to this ( didn't understand most of this one) www.ams.org/mcom/1996-65-213/S0025-5718-96-00696-5/S0025-5718-96-00696-5.pdf

function rand():Number {
	s1=((s1&4294967294)<<12)^(((s1<<13)^s1)>>19);
	s2=((s2&4294967288)<<4)^(((s2<<2)^s2)>>25);
	s3=((s3&4294967280)<<17)^(((s3<<3)^s3)>>11);
	var r:Number = (s1^s2^s3) * 2.3283064365e-10;
	r = (r<0) ? r+=1 : r;
	return r;
}

// see a visual comparison between this and actionscript's Math.random()

var canvas:BitmapData = new BitmapData(400,400,false, 0xCCCCCC);
addChild(new Bitmap(canvas));

var posX:Number;
var posY:Number;

addEventListener(Event.ENTER_FRAME, onLoop);

function onLoop(evt:Event):void {

	for (var i:int = 0; i<100; i++){
		posX = rand() * 180
		posY = rand() * 180
		canvas.setPixel( 100 + posX, 10 + posY, 0x000000);
	}
	
	for (i = 0; i<100; i++){
		posX = Math.random() * 180
		posY = Math.random() * 180
		canvas.setPixel( 100 + posX, 210 + posY, 0x000000);
	}
}

The above snippet demo’s an alternative random number generator that uses the Tausworthe method.

Top square is Tausworthe and bottom is Math.random()

I don’t actually know much about this, or fully understand how it works. I just saw it on a random reddit thread, googled about it for a few minutes and then ported it to actionscript.

There’s lots of talk about what the BEST random number generator is…. which one is the fastest, which one is the most random. etc… I don’t really know much about that, especially since I’m just playing around with code and I don’t need a RNG for some scientific experiment. For me, what’s nice about this approach is the three random seeds. For some reason, Math.random() doesn’t have a place where you can enter a seed for random numbers. Random seeds are very useful when you want to do something random but want to be able to replicate the random results at a later time. For instance:

var s1:Number= 0xFFFFFF;
var s2:Number = 0xCCCCCC;
var s3:Number= 0xFF00FF;

trace("first three values:");
trace(rand());
trace(rand())
trace(rand())

s1 = 0xFF;
s2 = 0xEFEFEF;
s3 = 19008;

trace("nfirst three values with different seeds:");
trace(rand());
trace(rand())
trace(rand())

s1 = 0xFFFFFF;
s2  = 0xCCCCCC;
s3 = 0xFF00FF;

trace("noriginal three values:");
trace(rand());
trace(rand())
trace(rand())

function rand():Number {
	s1=((s1&4294967294)<<12)^(((s1<<13)^s1)>>19);
	s2=((s2&4294967288)<<4)^(((s2<<2)^s2)>>25);
	s3=((s3&4294967280)<<17)^(((s3<<3)^s3)>>11);
	var r:Number = (s1^s2^s3) * 2.3283064365e-10;
	r = (r<0) ? r+=1 : r;
	return r;
}

/*
outputs:
first three values:
0.051455706589931385
0.050584114155822715
0.417276361484596

first three values with different seeds:
0.6032885762463134
0.9319786790304015
0.8631882804934321

original three values:
0.051455706589931385
0.050584114155822715
0.417276361484596
*/

I stumbled upon a bunch of other random number algorithms, maybe I’ll throw them in a class in the next couple days.