Crackable String Encoding

var encode:Object = new Object();
var decode:Object = new Object();
var a:Array = " abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890".split("");

// change this for different encoded results
var offset:int = 10;

for (var i:int = 0; i<a.length; i++){
	var index:int = (a.length - i - offset) % a.length;
	encode[a[i]] = a[index];
	decode[a[index]] = a[i];
}

function encodeString(str:String):String{
	return map(str, encode);
}

function decodeString(str:String):String{
	return map(str, decode);
}

function map(str:String, smode:Object):String{
	var n:String = "";
	for (var i:int = 0; i<str.length; i++){
		var char:String = str.charAt(i);
		var en:String = smode[char];
		if (en){
		    n += en;
		}else{
			n += char;
		}
	}
	return n;
}

// test out the functions

var input:String = "This is a regular string";

trace(input);

var encoded:String = encodeString(input);

trace("encoded: ", encoded);

trace("decoded: ",decodeString(encoded));

/*
outputs:

This is a regular string
encoded:  gSRH1RH1Z1IVTFOZI1HGIRMT
decoded:  This is a regular string

*/

The above demos an intentionally simple string encoding technique.

This is a technique I use if I need to encode strings but don’t care if someone figures out what the string value actually is. For me, this is more common than needing hard/impossible to crack string encoding algorithms. A good example is an e-card… a url for an ecard could look like this:

www.birthdaycardthing.com/?name=joe&age=32

or it could look like this:

www.birthdaycardthing.com/?i=brx&x=5p

I wrapped this snippet up into a class and made a few minor tweaks. The class is called SimpleCipher it has two static methods and one static property…

import com.actionsnippet.utils.SimpleCipher;
// same as offset above, but can be set at any time
// new encode and decode Objects will be calculated
SimpleCipher.offset = 1;
var input:String = "SimpleCipher encoding and decoding";
			 
trace("input: ", input);
			 
var encoded:String = SimpleCipher.encode(input);
			 
trace("encoded: ", encoded);
trace("decoded: ", SimpleCipher.decode(encoded));
/*
outputs:
input:  SimpleCipher encoding and decoding
encoded:  RhlokdBhogdq0dmbnchmf0 mc0cdbnchmf
decoded:  SimpleCipher encoding and decoding
*/

Download SimpleCipher Class
(this class uses a static initializer… see yesterdays post)