Browse the notebook

Category: one-liners

Math.random() * Math.random()

June 27, 2009By Zevan

var rand:Number = Math.random() * Math.random() * Math.random();

This is a trick I use when I need more contrast in my random numbers. In this case, the variable rand will get closer to the number 1 significantly less frequently than if you just used Math.random() once.

To illustrate this I created this snippet:

[SWF(width=800, height=600)]

var r:Number = Math.random() * Math.random() * Math.random();
var inc:int = 0;
var xp:Number = 10;
var yp:Number = 10;
var count:int = 1;

var compare:Shape = Shape(addChild(new Shape()));
compare.graphics.lineStyle(0,0x2222FF);

graphics.lineStyle(0,0x00000);
scaleX = scaleY = 2;

addEventListener(Event.ENTER_FRAME, onLoop);
function onLoop(evt:Event):void {
	
     r =  Math.random() * Math.random() * Math.random();

	 if (inc == 0){
		 graphics.moveTo(xp + inc, yp + 30 - r * 30);
	 }else{
		 graphics.lineTo(xp + inc, yp + 30 - r * 30);
	 }
	 
	 r = Math.random();
	  if (inc == 0){
		 compare.graphics.moveTo(xp + inc, yp + 70 - r * 30);
	 }else{
		 compare.graphics.lineTo(xp + inc, yp + 70 - r * 30);
	 }
	 inc++;
	 if (inc == 50){
		 inc = 0;
		 xp = 10 + count % 6 * 60;
		 yp = 10 + int(count / 6) * 80;
		 r = Math.random()*Math.random();
		 count++;
	 }
}

The blue lines plots normal Math.random() and the black lines plots Math.random()*Math.random()*Math.random()

Read snippet

Random Negative or Positive

June 17, 2009By Zevan

for (var i:int = 0; i<10; i++){
  // randomly set a variable to -1 or positive 1
  trace(int(Math.random()*2) - 1 | 1);
}

/* outputs something like this
1
1
-1
1
-1
-1
1
1
-1
-1
*/

The past few days I found myself using this one-liner a few times. Just a quick way to randomly get -1 or 1.

I was brainstorming today and wrote a weird/bad inline version of an old post:

var rand:Number = [-3, 2, 1, 1, 1, 0.5][int(Math.random() * 6)];

I need to install a related posts plugin for WordPress – would be nice if this post were related to my old post about Tausworthe random seeds.

Been posting medium/large snippets and snippets the relate to QuickBox2D – so today I figured I’d get back to basics…

Read snippet

for loop Fun

June 1, 2009By Zevan

var leng:int = 10;
for (var i:int = 0, j:int = leng;  i < leng; i++, j = leng - i){
	trace(i, j);
}

/*outputs
0 10
1 9
2 8
3 7
4 6
5 5
6 4
7 3
8 2
9 1
*/

Looping backwards and forwards.

Read snippet

Instantiate and Set Properties

May 17, 2009By Zevan

function create(obj:Class, props:Object):*{
	var o:* = new obj();
	for (var p:String in props){
		o[p] = props[p];
	}
	return o;
}

// test out the function

var txt:TextField = create(TextField, {x:200, y:100, selectable:false, text:"hello there", textColor:0xFF0000, defaultTextFormat:new TextFormat("_sans", 20)});
addChild(txt);

var s:Sprite = Sprite(addChild(create(Sprite, {x:100, y:100, rotation:45, alpha:.5})));

with (s.graphics) beginFill(0xFF0000), drawRect(-20,-20,40,40);

var blur:BlurFilter = create(BlurFilter, {blurX:2, blurY:8, quality:1});

s.filters = [blur];

This snippet shows a function called create() that takes two arguments. The first argument is the name of a class to instantiate. The second is an Object with a list of properties to set on a newly created instance of the class (referenced in the first argument).

This could be particularly useful for TextFields which for some reason have no arguments in their constructor.

This will currently only work for classes that have either all optional constructor arguments or no constructor arguments.

Read snippet

Canonical Representation of XOR

January 30, 2009By Zevan

// xor
trace(0 ^ 0);
trace(0 ^ 1);
trace(1 ^ 0);
trace(1 ^ 1);

trace("canonical representation of xor");
trace(xor(0, 0));
trace(xor(0, 1));
trace(xor(1, 0));
trace(xor(1, 1));

function xor(a:int, b:int):int{
	//1-a   is the same as   int(!a)
	return 1-a & b | a & 1-b;
}

/*
outputs:
0
1
1
0
canonical representation of xor
0
1
1
0
*/

I learned about this from reading The Elements of Computing Systems: Building a Modern Computer from First Principles By Noam Nisan and Shimon Schocken

Check out chapter 1 from the above link for an easy to understand description of the canonical representation of a boolean function.

Just a side note… this happens to be the 100th post on actionsnippet.com

Read snippet

Variable Swap

January 28, 2009By Zevan

//
// swap some variables
// all techniques except the first are from http://cpptruths.blogspot.com/2006/04/swapping-two-integers-in-one-liner.html
//
var a:Number = 1.1;
var b:Number= 2.2;

trace(a, b);

// best, fastest, easiest to read way
var t:Number= a;
a = b;
b = t;

trace(a, b);

// not recommended slower ways:

b=a+b-(a=b);

trace(a, b);

// xor versions will only work with ints and uints
trace("nxor kills decimals:");

// easy to understand xor version
a^=b;
b^=a;
a^=b;

trace(a, b);

// one line xor version

a=(b=(a=b^a)^b)^a;

trace(a, b);

/* outputs:
1.1 2.2
2.2 1.1
1.1 2.2

xor kills decimals:
2 1
1 2
*/

The above swaps variables a and b in a few different ways. The first way (using a temp variable) is the best and fastest way… the rest of the ways are just interesting and fun.

I was coding and something reminded me that there are obscure variable swapping techniques out there… so I figured I’d google for a bit…. there are tons of examples of these online – with lots of good explanations…. I got the above from this link.

Read snippet

Zeno’s [classic easeOut]

January 24, 2009By Zevan

stage.frameRate = 30;
var circle:Shape = Shape(addChild(new Shape()));
with(circle.graphics) beginFill(0x000000), drawCircle(0,0,10);
circle.y = 50;

addEventListener(Event.ENTER_FRAME, onLoop);
function onLoop(evt:Event):void {
	circle.x += (mouseX - circle.x) / 12;
}

Read snippet

E?

January 7, 2009By Zevan

trace(Math.pow((1+1/10000000),10000000));

trace(Math.E);

/*outputs :

2.7182816939803724
2.718281828459045

*/

E

2.7182818284590452353602874713526624977572470936999595749669676277240766303535
47594571382178525166427427466391932003059921817413596629043572900334295260595630
73813232862794349076323382988075319525101901157383418793070215408914993488416750
92447614606680822648001684774118537423454424371075390777449920695517027618386062
61331384583000752044933826560297606737113200709328709127443747047230696977209310
14169283681902551510865746377211125238978442505695369677078……

Read snippet

Clamp Math.max(Math.min())

January 6, 2009By Zevan

// this one-liner is good to know:
// Math.max(minValue, Math.min(maxValue, valueToClamp));

// wrapped in a function it looks like this:
const MIN:Number = 0;
const MAX:Number = 100;

function clamp(val:Number, min:Number = MIN, max:Number = MAX){
	return Math.max(min, Math.min(max, val))
}

for (var i:int = 0; i<1000; i++){
	var val:Number = Math.random()*1000 - 500;
    // clamp the above random value between -100 and +100
    trace(clamp(val, -100, 100));
}

Although I show a function implementation above, I use this technique inline a good deal. If there is some value that I need to clamp I’ll often just “max min it”:

var val:Number = Math.random()*1000;
// clamp it - 0-100
trace(Math.max(0, Math.min(100, val));

Read snippet

Unique ID

December 17, 2008By Zevan

trace((new Date()).getTime() + Math.random()*0xFFFFFF);

A hacky way to get a unique ID, although this isn’t, perfect it works well enough. For a project that you really expect to get huge amounts of traffic… you might consider using php’s uniqid() function and passing it into your swf. That said, the odds of two users getting the same two ID values are about as good as the odds of you winning the lottery twice in a row.

Here is a version wrapped in a function, with a prefix argument:

trace(uniqid("z"));

function uniqid(prefix:String):String{
return prefix + (new Date()).getTime() + Math.random()*0xFFFFFF;
}

Read snippet