[SWF(width = 500, height = 500, frameRate = 30)]
var canvas:BitmapData = new BitmapData(stage.stageWidth,stage.stageHeight,false, 0xFFFFFF);
var indexCanvas:BitmapData = new BitmapData(stage.stage.stageWidth, stage.stageHeight, false,
0xFFFFFF);
addChild(new Bitmap(canvas));
var s:Shape = new Shape();
var lineData:Array = [];
var dataIndex:int = 0;
trace(0xFFFFFF - 1)
var totalLines:int = 20000;
var iterations:int = 9;
var linesPerIter:int = totalLines / iterations;
var xp:int = stage.stageWidth / 2;
var yp:int = stage.stageHeight / 2;
var stepAmt:Number = 60;
var halfStepAmt:Number = stepAmt / 2;
addEventListener(Event.ENTER_FRAME, onDraw);
function onDraw(evt:Event):void {
if (lineData.length < totalLines){
generateData(linesPerIter);
}else{
stage.quality = "high";
addChild(s);
s.x = 0;
s.y = 0;
removeEventListener(Event.ENTER_FRAME, onDraw);
addEventListener(Event.ENTER_FRAME, onRun);
}
}
function onRun(evt:Event):void {
var currentIndex:int = indexCanvas.getPixel(mouseX, mouseY);
var currentLine:Array = lineData[currentIndex];
s.graphics.clear();
if (currentIndex != 0xFFFFFF){
s.graphics.lineStyle(3, 0xFF0000);
s.graphics.moveTo(currentLine[0], currentLine[1]);
s.graphics.lineTo(currentLine[2], currentLine[3]);
}
}
function generateData(num:int):void{
var rxA:int, rxB:int, ryA:int, ryB:int;
var g:Graphics = s.graphics;
for (var i:int = 0; i<num; i++){
rxA = xp;
ryA = yp;
xp += Math.round(Math.random() * stepAmt) - halfStepAmt;
yp += Math.round(Math.random() * stepAmt) - halfStepAmt;
if (xp > stage.stageWidth){
xp = stage.stageWidth - halfStepAmt;
}else
if (xp < 0){
xp = halfStepAmt;
}
if (yp > stage.stageHeight){
yp = stage.stageHeight - halfStepAmt;
}else
if (yp < 0){
yp = halfStepAmt;
}
rxB = xp;
ryB = yp;
lineData[dataIndex] = [rxA, ryA, rxB, ryB];
s.x = rxA;
s.y = ryA;
var endX:Number = rxB - rxA;
var endY:Number = ryB - ryA;
var m:Matrix = s.transform.matrix;
g.clear();
g.lineStyle(1, 0x000000, 0.3);
g.lineTo(endX, endY);
stage.quality = "high";
canvas.draw(s, m);
g.clear();
g.lineStyle(3, dataIndex);
g.lineTo(endX, endY);
stage.quality = "low";
indexCanvas.draw(s, m);
dataIndex++
}
}
I’m working on a data visualization that contains a long path made up of approximately one million points. There is some information associated with every two sets of coordinates that needs to be displayed when the user rolls their mouse over any part of the line.
I took a little time to think about the best way to do this and came up with a few techniques. The first one I tried seems to work nicely – this snippet is the proof of concept for that first technique. I tested this snippet with 1,000,000 xy coordinates and it works nicely. It takes a little while to draw though, so for the purposes of this demo I’ve just included 20,000 coordinates.
Have a look at the swf over at wonderfl.net
The way this works is by drawing lines to two different BitmapData instances. I draw anti-aliased slightly transparent lines to a BitmapData instance called “canvas” (this is added to the display list) – I then draw aliased lines to a BitmapData called “indexCanvas” (this is never added to the display list) – each aliased line uses an incremental value for its color – this incremental value is also the index for a two dimensional array containing the coordinate information for the aliased line. I use getPixel() on the “indexCanvas” and use the return value as the index for the 2D array. The data from the 2D array is used to draw a red line with the graphics class. This technique enables you to have many many rollovers and all you ever have to do is call getPixel() and use the returned color value to look up info about what you’re mouse is touching.
There are a few cool ways this could be repurposed and this is really only one solution to the problem of having many many things that you need to be able to rollover… there are others that don’t use BitmapData at all… I may write those up in the next couple of days.
